3

从一个完全空的 MXML 应用程序开始:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
    layout="absolute" >

</mx:Application>

什么是脚本:

  • 创建一个位图(这应该是一个BitmapData对象吗?)
  • 以编程方式用数据填充它(例如画一个圆圈)(有没有比重复调用更有效的方法BitmapData.SetPixel?)
  • 在应用程序中渲染它(例如在中间居中)(如何将位图显示到屏幕上?在线 Flash 示例显示调用myBitmap=new Bitmap(myBitmapData)then myBitmap.AddChild,但这会在 Flex 中引发错误)。

??

注意:目标不仅仅是在屏幕上显示一个圆圈,而是使用 SetPixel(或 ???)填充 Bitmap(或 BitmapData?或 ???)对象,然后将其内容显示到屏幕上,就像需要在图像处理或视觉效果应用中做。

4

2 回答 2

3

你有几个选择。首先是检查Degrafa 框架,它有一些非常棒的绘图工具,否则你需要添加一个脚本块并在函数中使用 AS3 绘图 api(在这种情况下可能会在 creationComplete 上调用:

private function handleCreationComplete():void
{
    var component:UIComponent = new UIComponent(); //needed to add to the flex display list
    var myCircle:Sprite = new Sprite();
    myCircle.graphics.beginFill(0xFFFFFF,1)
    myCircle.graphics.drawCircle(100,100,50);
    component.addChild(myCircle);
    this.addChild(component);
}

这不会使圆圈居中,但您可以弄清楚这一点。

您可以使用此函数从上述 UIComponent 中实际获取位图:

private function getBitmapData( target : UIComponent ) : BitmapData
   {
    var bd : BitmapData = new BitmapData( target.width, target.height );
    var m : Matrix = new Matrix();
    bd.draw( target, m );
    return bd;
   }

这里

于 2009-04-23T03:36:06.427 回答
2

这是一个完整的工作示例,我可以根据 Joel Hooks 的建议创建:

MXML 文件(ards.mxml):

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
       creationComplete="onCreationComplete()">

<mx:Script source="ards_script.as" />

</mx:Application>

脚本文件(ards_script.as):

import mx.core.UIComponent;

private function onCreationComplete():void
{
    // create a UIComponent and add it to the Flex display list
    var component:UIComponent = new UIComponent();
    component.width = this.width;
    component.height = this.height;
    component.x = 0;
    component.y = 0;
    this.addChild(component);

    // create a BitmapData object (basically an array of pixels) the same size as the screen    
    var bd : BitmapData = new BitmapData( component.width, component.height );

    // draw a green circle in the bitmap data
    var xCenter:int = component.width/2;
    var yCenter:int = component.height/2;
    var r:int = Math.min(xCenter,yCenter);
    var rSquare:int = r*r;
    var color:Number = 0x00ff00;
    for( var i:int=0; i<component.width; i++ )
    {
        for( var j:int=0; j<component.width; j++ )
        {
            var dX:int = i - xCenter;
            var dY:int = j - yCenter;
            var q:int = dX*dX + dY*dY;
            if( q < rSquare )
            {
                    bd.setPixel( i, j, color );
            }       
        }
    }

    // create a bitmap based on the data, and add it as a child to the UIComponent to be displayed
    // (if you try to add it directly to the Application, you get a runtime error)
    var bt:Bitmap = new Bitmap(bd);
    component.addChild(bt);    
}
于 2009-04-23T16:05:57.550 回答