mule - Mule 中的 Dataweave - 更改对象的值数组

Question

我在消息转换组件中获得了一个有效负载作为输入。它是一个带有对象的数组：

 [
      {
          "enterprise": "Samsung",
          "description": "This is the Samsung enterprise",
      },
      {
          "enterprise": "Apple",
          "description": "This is the Apple enterprise ",
      }
  ]

我有一个替换描述的变量，我想要的输出是：

[
      {
          "enterprise": "Samsung",
          "description": "This is the var value",
      },
      {
          "enterprise": "Apple",
          "description": "This is the var value",
      }
  ]

我尝试使用：

 %dw 2.0
 output application/java
 ---
 payload map ((item, index) -> {

     description: vars.descriptionValue
 })

但它返回：

 [
      {
          "description": "This is the var value",
      },
      {
          "description": "This is the var value",
      }
  ]

是否可以仅替换保留其余字段的描述值？避免在映射中添加其他字段。

Answer 1

有很多方法可以做到这一点。

一种方法是首先删除原始描述字段，然后添加新的

%dw 2.0
output application/java
---
payload map ((item, index) -> 
    item - "description" ++ {description: vars.descriptionValue}
)

否则，您可以使用mapObject迭代每个对象的键值对，并在键为描述时pattern matching添加for。case当我想做很多替换时，我更喜欢第二种方式。

%dw 2.0
output application/java
fun process(obj: Object) = obj mapObject ((value, key) -> {
    (key): key match {
        case "description" -> vars.descriptionValue
        else -> value
    }
})
---
payload map ((item, index) -> 
    process(item)
)