2

我正在尝试使用 Scalapack 计算许多大型矩阵的特征谱，而不是将每个矩阵分布在所有 32 个进程中。我宁愿将每个矩阵分布在 4 个进程中并并行计算 8 个矩阵。我知道如何使用 MPI_Comm_split 细分 MPI 网格，但我似乎 Scalapack 不采用自定义通信器。相反，它似乎使用了植根于 PVM 的 BLACS 网格。

如何在 Scalapack 中实现这个细分？

4

2 回答 2

1

这是通过BLACS网格设置完成的。

参考函数是

这些例程的文档指出：

这些例程采用可用的进程，并将它们分配或映射到 BLACS 进程网格中。

每个 BLACS 网格都包含在一个上下文（它自己的消息传递域）中，因此它不会干扰其他网格/上下文中发生的分布式操作。

可以重复调用这些网格创建例程以定义额外的上下文/网格。

这意味着您可以创建 8 个不同的网格并将每个网格传递ICONTXT给每个矩阵的 scalapack 例程。

他们都得到一个 IN/OUT 参数

ICONXT

（输入/输出）整数

在输入时，一个整数句柄指示用于创建 BLACS 上下文的系统上下文。用户可以通过调用 BLACS_GET 获得默认系统上下文。输出时，创建的 BLACS 上下文的整数句柄。

您可以以相同的方式递归地使用这些上下文。

于 2017-11-02T10:04:38.693 回答
1

我实施了@ztik 建议，这就是我想出的结果。它似乎工作：

program main
    use mpi
    implicit none
    integer              :: ierr, me, nProcs, color, i,j,k, my_comm, dims(2), global_contxt
    integer              :: cnt, n_colors, map(2,2)
    integer, allocatable :: contxts(:)
    integer, parameter   :: group_size = 4

    call MPI_Init(ierr)

    call MPI_Comm_size(MPI_COMM_WORLD, nProcs, ierr)
    call MPI_Comm_rank(MPI_COMM_WORLD, me, ierr)

    color = get_color(group_size)
    n_colors =  nProcs / group_size
    allocate(contxts(n_colors))

    dims = calc_2d_dim(group_size)

    call BLACS_GET(0, 0, global_contxt)
    if(me == 0) write (*,*) global_contxt
    contxts = global_contxt

    do k = 1,n_colors 
        ! shift for each context
        cnt = group_size * (k-1)
        if(me==0) write (*,*) "##############", cnt

        ! create map
        do i=1,2
            do j=1,2
                map(i,j) = cnt
                cnt = cnt + 1
            enddo
        enddo

        call BLACS_GRIDMAP(contxts(k), map, 2, 2, 2)
        do i = 0,nProcs
            if(i == me) then
                write (*,*) me, contxts(k)
            endif
            call MPI_Barrier(MPI_COMM_WORLD, ierr)
        enddo
    enddo

    call MPI_Finalize(ierr)
contains
    function get_color(group_size) result(color)
        implicit none
        integer, intent(in)     :: group_size
        integer                 :: me, nProcs, color, ierr, i, cnt

        call MPI_Comm_size(MPI_COMM_WORLD, nProcs, ierr)
        call MPI_Comm_rank(MPI_COMM_WORLD, me, ierr)

        if(mod(nProcs, group_size) /= 0) then
            write (*,*) "Nprocs not divisable by group_size", mod(nProcs, group_size)
            call MPI_Abort(MPI_COMM_WORLD, 0, ierr)
        endif

        color = 0
        do i = 1,me
            if(mod(i, group_size) == 0) then
                color = color + 1
            endif
        enddo
    end function get_color

    function calc_2d_dim(sz) result(dim)
        implicit none
        integer, intent(in)    :: sz
        integer                :: dim(2), cand

        cand = nint(sqrt(real(sz)))

        do while(mod(sz, cand) /= 0)
            cand = cand - 1
        enddo
        dim(1) = sz/cand
        dim(2) = cand
    end function calc_2d_dim

end program main
于 2017-11-02T15:59:52.430 回答