6

我正在尝试使用 DWM API 在 VB.NET 2010 应用程序中的表单中查看 Aero Glass，但正如函数调用所建议的那样，它将 Frame 的外观扩展到客户区域，如果表单没有边框，则不会发生任何事情并形成将变得不可见。那么，我可以得到无边框形式的 Aero 玻璃...... ??

4

1 回答 1

13

正如您所说，DwmExtendFrameIntoClientArea从字面上将窗口框架的透明玻璃效果扩展到其客户区域，这意味着如果您的表单FormBorderStyle设置为“无”，您的窗口将实际上是不可见的。

相反，您需要使用DwmEnableBlurBehindWindowAPI，它可以在窗口上启用玻璃状模糊效果，而不需要它具有框架/边框。它需要两个参数。第一个 ( hWnd) 是您希望应用背景模糊效果的表单句柄。第二个 ( pBlurBehind) 是通过引用传递的结构，其中包含效果的数据或参数。

因此，您还必须定义DWM_BLURBEHIND结构，它本身包含四个成员。第一个 ( dwFlags) 是常量值的按位组合，指示该结构的哪些成员已被设置。第二个 ( fEnable) 指示您是要启用还是禁用模糊效果。第三个 ( hRgnBlur) 允许您指定客户区域内将应用模糊效果的特定区域；将此设置为Nothing表示整个客户区域将具有模糊效果。第四个 ( fTransitionOnMaximized) 允许您指定表单的颜色是否应过渡以匹配最大化的窗口。

以下是您必须包含在代码中才能使用此函数的最终 API 声明：

<StructLayout(LayoutKind.Sequential)> _
Private Structure DWM_BLURBEHIND
    Public dwFlags As Integer
    Public fEnable As Boolean
    Public hRgnBlur As IntPtr
    Public fTransitionOnMaximized As Boolean
End Structure

Private Const DWM_BB_ENABLE As Integer = &H1
Private Const DWM_BB_BLURREGION As Integer = &H2
Private Const DWM_BB_TRANSITIONONMAXIMIZED As Integer = &H4

<DllImport("dwmapi.dll", PreserveSig:=False)> _
Private Shared Sub DwmEnableBlurBehindWindow(ByVal hWnd As IntPtr, ByRef pBlurBehind As DWM_BLURBEHIND)
End Sub

然后这是一个简单的例子，说明如何在特定表单上调用此函数：

Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
    MyBase.OnLoad(e)

    ''#Set the form's border style to None
    Me.FormBorderStyle = FormBorderStyle.None

    ''#Whatever region that you fill with black will become the glassy region
    ''# (in this example, the entire form becomes transparent)
    Me.BackColor = Color.Black

    ''#Create and populate the blur-behind structure
    Dim bb As DWM_BLURBEHIND
    bb.dwFlags = DWM_BB_ENABLE
    bb.fEnable = True
    bb.hRgnBlur = Nothing

    ''#Enable the blur-behind effect
    DwmEnableBlurBehindWindow(Me.Handle, bb)
End Sub

相反，如果您只想将模糊效果应用到表单的特定子区域，则需要为hRgnBlur成员提供有效区域，并将DWM_BB_BLURREGION标志添加到dwFlags成员。

您可以使用该Region.GetHrgn方法获取要指定为hRgnBlur成员的区域的句柄。例如，您可以使用以下代码代替上面的代码：

Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
    MyBase.OnLoad(e)

    ''#Set the form's border style to None
    Me.FormBorderStyle = FormBorderStyle.None

    ''#Fill the entire form with black to make it appear transparent
    Me.BackColor = Color.Black

    ''#Create a region corresponding to the area of the form you want to render as glass
    Using g As Graphics = Me.CreateGraphics
        Dim glassRect As New Rectangle(0, 0, 100, 150)
        Using rgn As New Region(glassRect)
            ''#Create and populate the blur-behind structure
            Dim bb As DWM_BLURBEHIND
            bb.dwFlags = DWM_BB_ENABLE Or DWM_BB_BLURREGION
            bb.fEnable = True
            bb.hRgnBlur = rgn.GetHrgn(g)

            ''#Enable blur-behind effect
            DwmEnableBlurBehindWindow(Me.Handle, bb)
        End Using
    End Using
End Sub

请注意，即使在指定要应用模糊效果的特定子区域时，我仍然将整个表单的背景颜色设置为黑色？这将导致我们指定的区域以玻璃状模糊效果进行渲染，而表单的其余部分则显示为透明。当然，您可以将表单的其余背景颜色设置为您想要的任何颜色（尽管确保像以前一样用黑色填充您想要显示为玻璃的矩形），但它将显示为部分透明，只是没有玻璃般的模糊效果。MSDN解释了为什么会这样：

当您将模糊效果应用到窗口的子区域时，窗口的 Alpha 通道将用于非模糊区域。这可能会导致窗口的非模糊区域出现意外的透明度。因此，在对子区域应用模糊效果时要小心。

就我而言，这使得仅将此效果应用于窗体窗口的子区域相对毫无价值。在我看来，唯一可能有意义的是，如果您想将任意非矩形形状渲染为玻璃状，而其余形状保持透明。

于 2010-12-12T06:30:51.240 回答