有趣的小问题:)
如果您仔细查看该图,则可以清楚地说明顺序:

绘制这些可能有很多解决方案,也许更优雅,但这是我的:
你知道斜边是当前线段计数+1的平方根,三角形的对边总是1。
您还知道角度的 Sine(Math.sin) 等于对边除以斜边。来自旧的助记符 SOH(Sine,Opposite,Hypotenuse),-CAH-TOA。
Math.sin(angle) = opp/hyp
您知道角度的正弦值,您知道两侧,但您还不知道角度,但您可以使用反正弦函数(Math.asin)
angle = Math.asin(opp/hyp)
现在您知道了每个线段的角度,并注意到它随着每条线的增加而增加。
现在您有了角度和半径(斜边),您可以使用极坐标到笛卡尔公式将该角度、半径对转换为x、y对。
x = Math.cos(angle) * radius;
y = Math.sin(angle) * radius;
由于您要求提供动作脚本解决方案,因此 Point 类已经通过polar()方法为您提供了此功能。您将半径和角度传递给它,它会在 Point 对象中返回您的 x 和 y。
这是一个绘制螺旋线的小片段。您可以通过在 Y 轴上移动鼠标来控制段数。
var sw:Number = stage.stageWidth,sh:Number = stage.stageHeight;
this.addEventListener(Event.ENTER_FRAME,update);
function update(event:Event):void{
drawTheodorus(144*(mouseY/sh),sw*.5,sh*.5,20);
}
//draw points
function drawTheodorus(segments:int,x:Number,y:Number,scale:Number):void{
graphics.clear();
var points:Array = getTheodorus(segments,scale);
for(var i:int = 0 ; i < segments; i++){
points[i].offset(x,y);
graphics.lineStyle(1,0x990000,1.05-(.05+i/segments));
graphics.moveTo(x,y);//move to centre
graphics.lineTo(points[i].x,points[i].y);//draw hypotenuse
graphics.lineStyle(1+(i*(i/segments)*.05),0,(.05+i/segments));
if(i > 0) graphics.lineTo(points[i-1].x,points[i-1].y);//draw opposite
}
}
//calculate points
function getTheodorus(segments:int = 1,scale:Number = 10):Array{
var result = [];
var radius:Number = 0;
var angle:Number = 0;
for(var i:int = 0 ; i < segments ; i++){
radius = Math.sqrt(i+1);
angle += Math.asin(1/radius);//sin(angle) = opposite/hypothenuse => used asin to get angle
result[i] = Point.polar(radius*scale,angle);//same as new Point(Math.cos(angle)*radius.scale,Math.sin(angle)*radius.scale)
}
return result;
}
这本可以用更少的行编写,但我想将其拆分为两个函数:一个只处理计算数字,另一个处理绘制线条。
以下是一些截图:



为了好玩,我在这里使用 ProcessingJS 添加了一个版本。运行有点慢,所以我会为此推荐 Chromium/Chrome。
现在您可以在此处实际运行此代码(上下移动鼠标):
var totalSegments = 850,hw = 320,hh = 240,segments;
var len = 10;
points = [];
function setup(){
createCanvas(640,480);
smooth();
colorMode(HSB,255,100,100);
stroke(0);
noFill();
//println("move cursor vertically");
}
function draw(){
background(0);
translate(hw,hh);
segments = floor(totalSegments*(mouseY/height));
points = getTheodorus(segments,len);
for(var i = 0 ; i < segments ; i++){
strokeWeight(1);
stroke(255-((i/segments) * 255),100,100,260-((i/segments) * 255));
line(0,0,points[i].x,points[i].y);
// strokeWeight(1+(i*(i/segments)*.01));
strokeWeight(2);
stroke(0,0,100,(20+i/segments));
if(i > 0) line(points[i].x,points[i].y,points[i-1].x,points[i-1].y);
}
}
function getTheodorus(segments,len){
var result = [];
var radius = 0;
var angle = 0;
for(var i = 0 ; i < segments ; i++){
radius = sqrt(i+1);
angle += asin(1/radius);
result[i] = new p5.Vector(cos(angle) * radius*len,sin(angle) * radius*len);
}
return result;
}
<script src="https://cdnjs.cloudflare.com/ajax/libs/p5.js/0.4.4/p5.min.js"></script>