2

我有一个正在开发的模块。我正在设置一些这样的属性：

$self->{FOO};
$self->{BAR};
$self->{FOOBAR};

而且，我想使用 AUTOLOAD 来帮助创建访问这些属性的方法。例如，$foo->Bar()返回 的值$self->{BAR}。没问题。一切都是标准的。

现在，我想创建别名方法。例如，如果有人说$obj->Fu();，我会回来$self->{FOO}。我想做的是创建一个$self->{FU}指向与$self->{FOO}. 这样，当我设置 的值时$self->{FOO}，$self-{FU}也会设置。这样，我不必对 AUTOLOAD 的工作方式进行各种更改，也不必记住$self->{FU}在我设置$self->{FOO}.

有什么简单的方法吗？

4

3 回答 3

10

是的，使用Moose，而不是尝试在哈希键之间进行显式映射。编写自己的访问器或使用 AUTOLOAD 是不必要的，而且出错的可能性要高得多：

package MyClass;

use Moose;
use MooseX::Aliases;

has foo => (
    is => 'rw', isa => 'Str',
    alias => 'fu',
);
has bar => (
    is => 'rw', isa => 'Str',
);
__PACKAGE__->meta->make_immutable;
no Moose;
1;

package main;
use strict;
use warnings;
use MyClass;
my $obj = MyClass->new;
$obj->foo("value");
$obj->fu("a new value");

# prints "foo has the value 'a new value'"
print "foo has the value '", $obj->foo, "'\n";
于 2010-10-10T05:03:02.757 回答
4

我会推荐Moose而不是你正在做的事情，但完成你所要求的最简单的方法可能是这样的：

sub Fu { shift->Foo(@_) }

这样，是否Foo自动加载都没有关系。

于 2010-10-10T05:10:08.853 回答
0

非 Moose 解决方案是在符号表中创建一个别名。这不是一件常见的事情，我怀疑无论你试图做什么都有更好的方法，Moose 或其他。如果您可以通过更好的设计或界面来避免它，请不要使用任何这些，这通常是解决此类问题的最佳解决方案。

在这个AUTOLOAD例程中，我查看%Aliases哈希以找出我必须定义的其他方法。当我有别名时，我会在符号表中创建正确的别名。这有点难看，但它避免了在调用堆栈中添加另一个实际方法：

#!perl

use 5.010;

{
package SomeClass;
use Carp;
use vars qw($AUTOLOAD);

sub new {
    return bless { 
        map { $_, undef } qw(FOO BAR FOOBAR)
        }, $_[0];
    };

my %Aliases = (
    FOO => [ qw(fu) ],
    );

sub AUTOLOAD {
    our $method = $AUTOLOAD;
    $method =~ s/.*:://;

    carp "Autoloading $method";

    {
    no strict 'refs';
    *{"$method"} = sub { 
        @_ > 1 
                ? 
            $_[0]->{"\U$method"} = $_[1]
                :
            $_[0]->{"\U$method"}
        };

    foreach my $alias ( @{ $Aliases{"\U$method"} } ) {
        *{"$alias"} = *{"$method"};
        }

    goto &{"$method"};
    }

    }

sub DESTROY { 1 }
}

my $object = SomeClass->new;

$object->foo(5);

say "Foo is now ",   $object->foo;
say "Foo is now ",   $object->foo(9);
say "Fu is now ",    $object->fu;
say "Fu is set to ", $object->fu(17);
say "Foo is now ",   $object->foo;

现在foo并fu 访问相同的东西：

Foo is now 5
Foo is now 9
Fu is now 9
Fu is set to 17
Foo is now 17
于 2010-10-11T18:29:59.230 回答