1

我目前正在尝试构建自己的引导加载程序，并注意到一些奇怪的东西。

当下面的代码用 NASM 或 Yasm 组装而没有标记的 NOP 命令时，二进制文件中缺少以下 CALL。在包含 NOP 的情况下，CALL 已正确组装，但二进制文件中不存在操作码 0x90 (NOP)（由于 NOP 的性质，稍后可以理解）。

to_hex_ascii:
        add al, '0'
        cmp al, 0x3a
        jl .end
;           add al, 0x07
            add al, 0x27
    .end:
        ret

print_word_hex:
        push bp
        mov bp, sp

        mov dx, [bp + 4]
        push dx
        mov al, dh
        push ax             ;\
        nop                 ; | <- NOP in question
        call print_lsb_hex  ; print_lsb_hex(ax);
        add sp, 2           ;/
        pop dx
        jmp print_lsb_hex.continue
print_lsb_hex:
        push bp
        mov bp, sp

        mov dl, [bp + 4]
    .continue:
        mov ah, 0x0e
        ; 0xf0
        mov al, dl
        and al, 0xf0
        shr al, 4
        call to_hex_ascii
        int 0x10  ; BIOS print call
        ; 0x0f
        mov al, dl
        and al, 0x0f
        call to_hex_ascii
        int 0x10  ; BIOS print call

        pop bp
        ret
4

1 回答 1

2

反斜杠字符“\”作为一行的最后一件事，是 Nasm 的“行继续字符”。通过将其放在注释中，注释将继续到下一行 - 注释掉 nop 或 call。（就这样消失不是 nop 的本性！）。丢掉它，或者在它后面放点东西。

——弗兰克·科特勒

从 NASM 手册中，3.1 NASM 源代码行的布局：

NASM 使用反斜杠 ( \) 作为行继续符；如果一行以反斜杠结尾，则下一行被认为是反斜杠结尾行的一部分。

于 2015-04-30T10:32:05.090 回答