1

我正在尝试制作一款游戏，您可以在其中捕捉在空中随机移动的浮灯。在游戏中会有 3 个不同的盒子可以放置浮灯，所以也会有 3 个不同的灯。

灯工作正常，我可以随意拖动它们。

我的问题是如何捕捉它们并重新生成它们。我想使用kill()您在flixel.FlxNapeSprite.

当你抓住它们时，你应该将它们移动到正确的盒子里，当它们进入盒子时，它们应该被杀死，你得到分数，并重新生成一个新的随机光。

到目前为止的游戏图片链接

如何杀死某个区域内的光物体？

4

1 回答 1

2

我猜盒子也是FlxNapeSprites？通常你会在这里设置一个碰撞回调，只要两个颈背物体的碰撞箱重叠（在这种情况下是灯光和盒子），就会调用它。napeDebugEnabled = true您可以使用或通过按下 flixel 调试器覆盖右上角的“N”按钮来显示颈背主体。

下面是一个如何使用 Flixel + Nape 设置简单碰撞回调的简单示例：

package;

import flixel.addons.nape.FlxNapeSprite;
import flixel.addons.nape.FlxNapeState;
import flixel.util.FlxColor;
import nape.callbacks.CbEvent;
import nape.callbacks.CbType;
import nape.callbacks.InteractionCallback;
import nape.callbacks.InteractionListener;
import nape.callbacks.InteractionType;
import nape.phys.BodyType;
using flixel.util.FlxSpriteUtil;

class PlayState extends FlxNapeState
{
    override public function create()
    {
        super.create();
        bgColor = FlxColor.BLACK;
        napeDebugEnabled = true;

        var light = new Light(10, 10);
        var box = new Box(10, 100);

        add(light);
        add(box);

        light.body.velocity.y = 200;

        FlxNapeState.space.listeners.add(new InteractionListener(
            CbEvent.BEGIN, 
            InteractionType.COLLISION, 
            Light.CB_TYPE,
            Box.CB_TYPE,
            collideLightBox));
    }

    function collideLightBox(callback:InteractionCallback)
    {
        var light:Light = cast callback.int1.castBody.userData.sprite;
        light.kill();
    }
}

class Light extends FlxNapeSprite
{
    public static var CB_TYPE(default, null) = new CbType();

    public function new(x:Float, y:Float)
    {
        super(x, y);
        makeGraphic(10, 10, FlxColor.TRANSPARENT);
        var radius = 5;
        drawCircle(5, 5, radius, FlxColor.WHITE);
        createCircularBody(radius);
        body.cbTypes.add(CB_TYPE);
        // we need this to get the Light instance in the callback later
        body.userData.sprite = this;
    }
}

class Box extends FlxNapeSprite
{
    public static var CB_TYPE(default, null) = new CbType();

    public function new(x:Float, y:Float)
    {
        super(x, y);
        makeGraphic(100, 50, FlxColor.GREEN);
        createRectangularBody(width, height);
        body.cbTypes.add(CB_TYPE);
        body.type = BodyType.STATIC;
    }
}

请务必查看官方FlxNape演示。Nape网站也有一些非常有用的示例 + 文档。

于 2015-04-21T15:36:11.783 回答