string - 如何在 XSLT 中将字符串格式化为 Pascal 大小写？

Question

我正在尝试在 XSLT 中格式化字符串，这些字符串需要采用帕斯卡大小写，才能正确用于我正在使用的应用程序。

例如：

this_text会变成ThisText
this_long_text会变成ThisLongText

是否也可以在可以将输入发送到格式的位置进行设置，这样我就不必多次重新创建格式？

Answer 1

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vLower" select=
  "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:variable name="vUpper" select=
  "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:call-template name="Pascalize">
   <xsl:with-param name="pText" select="concat(., '_')"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="Pascalize">
  <xsl:param name="pText"/>

  <xsl:if test="$pText">
   <xsl:value-of select=
    "translate(substring($pText,1,1), $vLower, $vUpper)"/>

   <xsl:value-of select="substring-before(substring($pText,2), '_')"/>

   <xsl:call-template name="Pascalize">
     <xsl:with-param name="pText"
       select="substring-after(substring($pText,2), '_')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时：

<t>
  <a>this_text</a>
  <b>this_long_text</b>
</t>

产生所需的结果：

<t>
    <a>ThisText</a>
    <b>ThisLongText</b>
</t>

顺便说一句，这是camelCase，这是PascalCase

Answer 2

两年后，这里出现了 XSLT 2.0 解决方案：

<xsl:function name="fn:pascal-case">
    <xsl:param name="string"/>
    <xsl:value-of select="string-join(for $s in tokenize($string,'\W+') return concat(upper-case(substring($s,1,1)),substring($s,2)),'')"/>
</xsl:function>

它会将“this_long_text”或“this-long-text”转换为“ThisLongText”，因为它会中断任何非单词字符。

在我最熟悉的正则表达式风格（perl、pcre 等）中，下划线被认为是 '\w' 字符类的一部分（因此不是 \W 的一部分），但对于 XSLT 2.0，使用 XSD 数据类型（ http://www.w3.org/TR/xmlschema-2/) 和 '\w' 定义为：

[#x0000-#x10FFFF]-[\p{P}\p{Z}\p{C}] (all characters except the set of "punctuation", "separator" and "other" characters)

所以 '\W' 包括一个下划线。

Answer 3

这个版本对我有用。我添加了一个选择，当不再存在下划线时输出字符串的“其余部分”。

<xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

<xsl:template name="Pascalize">
    <xsl:param name="pText" />
    <xsl:if test="$pText">
        <xsl:value-of select="translate(substring($pText,1,1), $vLower, $vUpper)" />
        <xsl:choose>
            <xsl:when test="contains($pText, '_')"> 
                <xsl:value-of select="substring-before(substring($pText,2), '_')" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="substring($pText,2)" />
            </xsl:otherwise>
        </xsl:choose>
        <xsl:call-template name="Pascalize">
            <xsl:with-param name="pText" select="substring-after(substring($pText,2), '_')" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

此外，万一有人来这里寻找相反的过程（我今天碰巧也需要，但找不到任何地方的一个例子）......

<xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

<xsl:template name="TitleCase">
    <xsl:param name="pText" />
    <xsl:call-template name="TitleCase_recurse">
        <xsl:with-param name="pText" select="concat(translate(substring($pText,1,1), $vLower, $vUpper), substring($pText,2))" />
    </xsl:call-template>
</xsl:template>

<xsl:template name="TitleCase_recurse">
    <xsl:param name="pText" />
    <xsl:if test="string-length($pText) &gt; 1">
        <xsl:if test="not(substring($pText,1,1) = ' ' and substring($pText,1,1) = ' ')">
            <xsl:value-of select="substring($pText,1,1)" />
        </xsl:if>
        <xsl:if test="translate(substring($pText,1,1), $vLower, $vUpper) != substring($pText,1,1)">
            <xsl:if test="translate(substring($pText,2,1), $vLower, $vUpper) = substring($pText,2,1)">
                <xsl:text> </xsl:text>
            </xsl:if>
        </xsl:if>
        <xsl:call-template name="TitleCase_recurse">
            <xsl:with-param name="pText" select="substring($pText,2)" />
        </xsl:call-template>
    </xsl:if>
    <xsl:if test="string-length($pText) = 1">
        <xsl:value-of select="$pText" />
    </xsl:if>
</xsl:template>

我喜欢在我完全有意识地放弃几个小时后，我的潜意识大脑弹出一个答案。;-)

Answer 4

我试图通过以下 XLST 函数调用来实现“pascalizing”：

<xsl:value-of select="fn:replace(@name,'_(\w{1})','\U$1')"/>

不幸的是，处理器抛出错误消息“replace() 中的替换字符串无效：\ 字符必须后跟 \ 或 $”

问题是 \U 修饰符，它应该对匹配的模式进行大写转换。如果我将其更改为

<xsl:value-of select="fn:replace(@name,'_(\w{1})','\\U$1')"/>

输出字符串包含序列 '\U' 因为它现在已被转义 - 但我不想转义它，我希望它确实有效 ;-) 。我做了测试

<xsl:value-of select="fn:replace(@name,'_(\w{1})','$1')"/>

（不将匹配转换为大写）并且效果很好。但当然它没有大写，只是删除下划线并自行替换下划线后面的字母而不是大写。我在这里做错了什么，或者我的 XSLT 处理器的正则表达式实现中根本不支持 \U 修饰符？

Answer 5

多亏了 Dimitre，我才得以顺利到达那里。通过 Pascalize 模板运行我的字符串时，最后一个 '_' 之后的位被切断。可能有一种更清洁的方法，但这是我使用的代码：

<xsl:template name="Pascalize">
    <xsl:param name="pText"/>

    <xsl:if test="$pText">
        <xsl:value-of select="translate(substring($pText,1,1), $vLower, $vUpper)"/>

        <xsl:value-of select="substring-before(substring($pText,2), '_')"/>

        <xsl:call-template name="Pascalize">
            <xsl:with-param name="pText" select="substring-after(substring($pText,2), '_')"/>
        </xsl:call-template>

        <xsl:call-template name="GrabLastPart">
            <xsl:with-param name="pText" select="$pText"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template name="GrabLastPart">
    <xsl:param name="pText"/>

    <xsl:choose>
        <xsl:when test="contains($pText, '_')">
            <xsl:call-template name="GrabLastPart">
                <xsl:with-param name="pText" expr="substring-after($pText, '_')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="substring($pText, 2)"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>