1

我试图通过特征值对 PROC FACTOR 中的因素进行加权，但遇到了一些困难。我有一个解决方案，但在我看来应该有一个更直接的方法来做到这一点。

** Get factors and eigenvalues;
ods output Eigenvalues=MyEigenVals
proc factor data=MyData method=principal out=MyData;
    var X1 X2 X3 X4 X5 X6;
run;
ods output close;

** Transpose the eigenvalues;
proc transpose data=MyEigenVals out=MyEigenVals(drop=_NAME_) prefix=eigenval;
    id Number;
    var Eigenvalue;
run;

** Merge the data and fill down the eigenvalues;
data MyData;
    merge MyData MyEigenVals;
    retain E1 E2 E3 E4 E5 E6;
    if _n_=1 then do;
        E1 = eigenval1;
        E2 = eigenval2;
        E3 = eigenval3;
        E4 = eigenval4;
        E5 = eigenval5;
        E6 = eigenval6;
    end;
    ** weight each factor by its eigenvalue;
    factor1 = factor1 * E1;
    factor2 = factor2 * E2;
    factor3 = factor3 * E3;
    factor4 = factor4 * E4;
    factor5 = factor5 * E5;
    factor6 = factor6 * E6;
run;

如您所见，这似乎不是完成我的任务的一种非常直接的方式。这里的任何人都可以帮我解决这个问题吗？甚至可能吗？

4

1 回答 1

1

您绝对可以更有效地组合它；至少，您可以简化最后一个数据步骤。

data mydata;
if _n_=1 then set MyEigenVals;
set mydata;
array factor[6];
array Eigenval[6];
do _i = 1 to dim(factor);
  factor[_i] = factor[_i]*eigenval[_i];
end;
run;

SET自动保留变量。

其次，您可以根据使用结果的方式跳过乘法。您可能可以使用weight语句将特征值用作权重 - 取决于您稍后用于分析数据的程序。我不知道这是否会给您带来很多好处，但是它可以使您免于修改可能更可取的原始值。

于 2014-04-09T18:25:19.557 回答