1

我尝试用 GNUPLOT 制作这个直方图，但我不明白如何显示国家的名称（我也放了我的 dati.dat 文件）。

这里的代码：

reset

set terminal pngcairo size 500,500 enhanced font 'Verdana,10'
set output 'Err_rev.png'

# this command to modify the orientation of the png 
#convert -rotate 90 Err_rev.png Err_rev_out.png

set key at graph 0.24, 0.80 horizontal samplen 0.1
set style data histogram
set style histogram cluster gap 2
set style fill solid border -1
set boxwidth 0.8
set xtic rotate by 90 scale 0
unset ytics
set y2tics rotate by 90
set yrange [0:100]; set xrange [*:*]
set y2label 'Paragone tra Nazioni: Domicilio - Hospice ' offset -2.5
set xlabel ' '
set size 1, 0.96
set label 1 'Nazioni' at graph 0.5, -0.1 centre rotate by 180
set label 2 'Domicilio' at graph 0.135, 0.83 left rotate by 90
set label 3 'Hospice' at graph 0.21, 0.83 left rotate by 90
p 'dati.dat' u 2 title ' ', '' u ($2/2.0+rand(0)/10.0) title ' ', '' u 0:(0):xticlabel(1) w l title ''

这里是file.dat：

Inghilterra 63 29
Belgio 71.6 9.9
Germania 66 14.8
Olanda 83.1 10.5
Portogallo 50.1 35.7
Spagna 60.1 16.8
Italia 76.1 12

非常感谢。

4

1 回答 1

1

要设置 xtic 标签，您可以using 2:xtic(1)在第一个命令中使用。要正确查看标签，您必须将 xtics 的对齐方式设置为right.

您可以包含转换命令以在脚本中旋转绘图。用 调用它system。您必须set output在此之前使用无文件名来指示该文件必须被刷新和关闭。

更改后的脚本是：

reset

set terminal pngcairo size 500,500 enhanced font 'Verdana,10'
set output 'Err_rev.png'

set key at graph 0.24, 0.80 horizontal samplen 0.1
set style data histogram
set style histogram cluster gap 2
set style fill solid border -1
set boxwidth 0.8
set xtic rotate by 90 scale 0 right
unset ytics
set y2tics center rotate by 90
set yrange [0:100]; set xrange [*:*]
set y2label 'Paragone tra Nazioni: Domicilio - Hospice ' offset -2.5
set size 1, 0.96
set label 1 'Nazioni' at graph 0.5, char 1 centre rotate by 180
set label 2 'Domicilio' at graph 0.135, 0.83 left rotate by 90
set label 3 'Hospice' at graph 0.21, 0.83 left rotate by 90

plot 'dati.dat' u 2:xtic(1) title ' ', '' u ($2/2.0+rand(0)/10.0) title ' '

set output
# this command to modify the orientation of the png 
system('convert -rotate 90 Err_rev.png Err_rev_out.png')

结果Err_rev_out.png（使用版本 4.6.3）：

在此处输入图像描述

绘制水平直方图的另一种方法是使用boxxyerrorbars样式，这也需要一些但其他技巧。Gnuplot 交换轴

于 2014-02-05T19:52:27.213 回答