2

我有两个包含以下内容的文本文件：

文件 1.txt：

ProcessId  VirtualSize  
5752       74649600     
3932       76843610
1357       90215638
& so on....

文件2.txt：

Notepad.exe pid: 3932 Linux
Notepad.exe pid: 1357 Macos
Notepad.exe pid: 5752 Windows
& so on....

现在，我们可以看到两个文件中的进程 ID 相同（匹配），所以我想生成一个合并的单个输出文件（匹配两个文件中的 processId），它应该具有以下内容：

输出.txt：

Windows 74649600  
Linux  76843610
Macos  90215638 
& so on....

我在下面尝试过，它正在运行但没有得到所需的输出：

@echo off
(for /f "skip=1 tokens=1,2" %%a in (file1.txt) do (
for /f "tokens=5" %%c in ('find " %%a " ^< file2.txt ') do echo %%c %%b
))>Output.txt

EDIT1： 如果我想用字符串永久修复/设置“Output.txt”的前两行，我应该添加什么：

This output is for first server
Applcation Memory(GB )

IE：

输出.txt：

This output is for first server
Applcation Memory(GB)
Windows  74649600  
Linux  76843610
Macos  90215638 
& so on....
4

2 回答 2

2

您的第二个 FOR 应该类似于以下内容。"tokens=5" 部分选择第 5 个标记，仅此而已。您需要令牌 3 和 5。

(for /f "skip=1 tokens=1,2" %%a in (file1.txt) do (
    for /f "tokens=3,5" %%x in ('find " %%a " ^< file2.txt ') do echo %%b %%y
))

如果 File1 和 File2 很长，则该脚本可以工作，但速度会很慢。我编写了一个脚本，重新格式化 file1 和 file2 以使 PID 成为每一行的第一件事。然后，使用 SORT 按 PID 组织文件。最后，扫描已排序的输出以查找具有匹配 PID 的行对。

有点长，但很容易看出它是如何工作的。

@echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

set INPUT1=file1.txt
set INPUT2=file2.txt
set OUTFILE=Outfile.txt
set TMPFILE=OutfileTMP.txt
set OUT=^>^>%OUTFILE%

if exist %OUTFILE% del %OUTFILE%
if exist %TMPFILE% del %TMPFILE%

call :ReadFile1
call :ReadFile2

sort < %OUTFILE% > %TMPFILE%
del %OUTFILE%
echo This output is for HFM server%OUT%
echo Applcation Memory(GB )%OUT%

set LASTPID=-
set LASTSIZE=-

for /f "tokens=1,2,3" %%a in (%TMPFILE%) do (
    if "%%b"=="1" set LASTPID=%%a&set LASTSIZE=%%c
    if "%%b"=="2" (
        if "%%a"=="!LASTPID!" (
            echo %%c !LASTSIZE! %OUT%
        ) else (
            echo Error: Not Matched: 1:!LASTPID!,!LASTSIZE!, 2:%%a %%c
        )
    )
)

del %TMPFILE%

goto :EOF


:ReadFile1
    for /f "skip=1 tokens=1,2" %%a in (%INPUT1%) do echo %%a 1 %%b %OUT%
    goto :EOF

:ReadFile2
    for /f "tokens=3,5" %%a in (%INPUT2%) do echo %%a 2 %%b %OUT%
    goto :EOF
于 2013-10-16T03:54:05.383 回答
1

关于什么：

@echo off

echo This output is for HFM server > out.txt
echo Applcation Memory(GB) >>out.txt

for /f "skip=1 tokens=1,2" %%a in (file1.txt) do (
   for /f "skip=2 tokens=5" %%c in ('find " %%a " file2.txt 2^>nul') do ( 
     echo %%c %%b >>out.txt
  )
)

?

于 2013-10-16T04:36:43.923 回答