5

我对宏有一个相当简单的问题。在其中，我将一个公式分配给一个单元格。我希望它不要一开始就计算它，只有在宏的其他部分完成后才进行计算。我以为我会做这样的事情：

Application.Calculation = xlCalculationManual
Cells(StartRow, 4 + i).Formula = "FORMULA"
...
Application.Calculation = xlCalculationAutomatic

但这不起作用。它会停止自动计算，但不会停止该单元格 - 在我分配公式后它仍然会立即执行计算。有没有办法跳过它？

为了澄清这一点的确切目的：在我的实际代码中，我将一个公式分配给一个循环中的一组单元格。每次我将它分配给一个单元格时 - 它都会计算它。我想如果我首先将它们全部分配然后进行计算 - 它会更快。事实上它是。因此，我没有将其分配给循环，而是将其分配给第一个单元格，然后进行自动填充。自动填充公式等到我启用自动计算并且我得到一个更快的宏。但是，仍然会计算初始分配，这使得宏几乎慢了两倍。

4

2 回答 2

7
  1. 将公式放在带有前缀字符的单元格中
  2. 继续宏
  3. “激活”公式

例如：

Sub dural()
    With Range("A1")
        .Value = "'=1+2"
        MsgBox " "
        .Value = .Value
    End With
End Sub
于 2013-08-24T13:01:23.960 回答
3

@Alex，您可以将计算延迟为@Gary 回答。但是，您问这个问题是因为在分配公式时需要“通过单元格循环速度” ，对吗？

如果是，从我的角度来看，如果在所有公式都分配到 Excel 表中之前您不使用公式，那么通过使用数组一次编写所有公式（VBA 中的一个步骤），您将获得很大的速度）。

过程是：首先将所有公式放入一个VBA字符串数组中，然后再使用例如Range("B1:B100").Formula = ArrayWithFormulas. 在该示例中，您一次分配 100 个公式，中间没有重新计算。

如果使用数组将所有单元格写入一个单元格而不是逐个单元格地写入，您将看到速度有很大的提高！cells(r,c+i)（如果您有很多单元格要通过，请不要循环使用）。这里有一个例子：

Sub CreateBunchOfFormulas()
  Dim i As Long
  Dim ARRAY_OF_FORMULAS() As Variant 'Note: Don't replace Variant by String!
  ReDim ARRAY_OF_FORMULAS(1 To 100, 1 To 1) 
                          ' For Vertical use: (1 to NumRows,1 to 1)
                          ' for Horizontal:   (1 to 1,1 to NumCols)
                          ' for 2D use:  (1 to NumRows,1 to NumCols)
  'Create the formulas...
  For i = 1 To 100
     ARRAY_OF_FORMULAS(i, 1) = "=1+3+" & i ' Or any other formula...
  Next i

  ' <-- your extra code here...
  '      (New formulas won't be calculated. They are not in the Excel sheet yet!
  '       If you want that no other old formula to recalculate use the old trick:
  '      Application.Calculation = xlCalculationManual )

  'At the very end, write the formulas in the excel at once...
  Range("B1:B100").Formula = ARRAY_OF_FORMULAS

End Sub

如果您想在新公式中额外延迟，那么您可以使用@Gary 技巧，但适用于一个范围，而不是单个单元格。'为此，以like开头的公式'=1+2并在末尾添加以下代码：

  '... previous code, but now formulas starting with (')
  Range("B1:B100").Formula = ARRAY_OF_FORMULAS   
  'Formulas not calculated yet, until next line is executed
  Range("B1:B100").Value  = Range("B1:B100").Value ' <~~ @Gary's trick
End Sub

最后，一个小片段：如果您的公式是水平排列的（意味着一个公式用于 A 列，另一个用于 B 列等）并且只有少数列，那么您可以记住先前代码的较短版本：

Dim a as Variant 'Note that no () needed
a = Array("=1+3","=4+8","=5*A1","=sum(A1:C1)")
Range("A1:D1").Formula = ARRAY_OF_FORMULA    ' Just a single row
' or...
Range("A1:D100").Formula = ARRAY_OF_FORMULA  ' If you want to repeat formulas
                                             ' in several rows.

最后，如果您想要一种在公式中使用相对引用的简单方法，您可以使用该方法.FormulaR1C1而不是之前的所有代码示例....Formula

希望这可以帮助！

于 2013-10-10T13:59:36.760 回答