244

I'm running RHEL 5.1 and use gcc.

How I tell cmake to add -pthread to compilation and linking?

4

4 回答 4

272

@Manuel 在那里。您也可以添加编译器选项，如下所示：

如果您有 CMake 3.1.0+，这将变得更加容易：

set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)
target_link_libraries(my_app PRIVATE Threads::Threads)

如果您使用的是 CMake 2.8.12+，则可以将其简化为：

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  target_compile_options(my_app PUBLIC "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

较旧的 CMake 版本可能需要：

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  set_property(TARGET my_app PROPERTY COMPILE_OPTIONS "-pthread")
  set_property(TARGET my_app PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

如果你想在 CMake 3.1+ 中使用前两种方法之一，你也需要set(THREADS_PREFER_PTHREAD_FLAG ON)那里。

于 2015-04-25T23:29:14.663 回答
209

以下内容应该是干净的（使用find_package）并且可以工作（调用 find 模块FindThreads）：

cmake_minimum_required (VERSION 2.6) 
find_package (Threads)
add_executable (myapp main.cpp ...)
target_link_libraries (myapp ${CMAKE_THREAD_LIBS_INIT})
于 2011-01-23T13:19:34.727 回答
34

这是正确的答案：

ADD_EXECUTABLE(your_executable ${source_files})

TARGET_LINK_LIBRARIES( your_executable
pthread
)

相当于

-lpthread
于 2009-10-31T20:09:37.123 回答
5

target_compile_options上面的解决方案是错误的，它不会链接库。

利用：

SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -pthread")

或者

target_link_libraries(XXX PUBLIC pthread)

或者

set_target_properties(XXX PROPERTIES LINK_LIBRARIES -pthread)

于 2021-01-12T08:41:12.443 回答