1

我首先用 C++ 创建了一个类似的程序，然后我决定尝试用 x86 汇编语言（我在大学里教过的那种汇编语言）来编写它。我已经完成了 C++ 版本，我的汇编版本也快完成了。

我对两个版本都做了一些桌面检查，首先使用 (2400, 3750)。我在两个版本中都得到了相同的 LCM 结果，这很好。但是，当我使用更大的数字（19000、8200）时，我的汇编程序崩溃了，而我的 C++ 版本显示了正确的结果。我怀疑这与我的程序集变量大小和/或我在计算 LCM 时用于除法的寄存器有关。

我通过输出被除数（第一个数字乘以第二个数字）和除数（GCD 结果）来测试我的 LCM 计算（减去除法运算）。我得到了正确的测试结果，所以我认为我的寄存器使用有问题。在此之前我已经测试了我的 GCD 计算，所以这不应该是问题的一部分。

%include "macros.s"

.DATA

num_lbl:   DB   "> Numbers (2): ", 0
gcd_lbl:   DB   "*** GCD: ", 0
lcm_lbl:   DB   "*** LCM: ", 0

num1:   DD   0
num2:   DD   0

num1_cpy:   DD   0
num2_cpy:   DD   0

gcd:   DD   0
lcm:   DD   0

.CODE
.STARTUP

xor       EAX, EAX
xor       EBX, EBX
xor       ECX, ECX
xor       EDX, EDX
xor       EDI, EDI
xor       ESI, ESI

main:
     nwln
     nwln
     PutStr   num_lbl
     nwln
     nwln
     GetLInt   [num1]
     GetLInt   [num2]

     mov   EAX, [num1]
     mov   [num1_cpy], EAX
     mov   EBX, [num2]
     mov   [num2_cpy], EBX

     call   calc_euclidean
     call   calc_lcm

     nwln
     PutStr   gcd_lbl
     PutLInt   [gcd]
     nwln
     PutStr   lcm_lbl
     PutLInt   [lcm]
     nwln

     .EXIT

calc_euclidean:
               mov   EAX, [num2]
               cmp   EAX, 0
               jne   chk_swap

               mov   EAX, [num1]
               mov   [gcd], EAX

               ret

calc_lcm:
         mov   EAX, [num1_cpy]
         mov   EDX, [num2_cpy]
         mul   EDX

         mov   EDI, EAX

         xor   EBX, EBX

         mov   EDX, EDI
         shr   EDX, 16
         mov   EAX, EDI
         mov   BX, [gcd]
         div   BX

         mov   SI, AX
         mov   [lcm], SI

         ret         

chk_swap:
         mov   EAX, [num1]
         mov   EBX, [num2]
         cmp   EAX, EBX
         jl    swap

after_check:
            jmp   loop

swap:
     mov   EAX, [num1]
     mov   EBX, [num2]

     ; temp
     mov   ECX, [num2]

     ; num2 = num1
     ; num1 = temp
     mov   EBX, EAX
     mov   EAX, ECX

     mov   [num1], EAX
     mov   [num2], EBX

     jmp   after_check

loop:
     mov   EDX, [num1]
     shr   EDX, 16
     mov   EAX, [num1]
     mov   BX, [num2]
     div   BX

     mov   EDI, [num1]
     mov   ESI, [num2]
     mov   EDI, ESI
     mov   [num1], EDI
     mov   [num2], EDX

     jmp   calc_euclidean
4

1 回答 1

3

问题出在calc_lcm程序中：

         mov BX, [gcd]
         div BX

         mov SI, AX
         mov [lcm], SI

当num1是 19200 和num28200 时，gcd变为 200。在这里，您尝试通过将num1和num2(19200 * 8200 = 157440000) 的乘积除以gcd(200) 来计算 lcm(19200, 8200)：

157440000 / 200 = 787200

编辑：修正错字。

787200 不适合 16 位。您需要将代码转换为使用 32 位div而不是 16 位div来处理比现在更大的数字。

所以它会是：

编辑：添加代码。

xor    ebx,ebx   ; this you have already.
mov    bx,[gcd]
xor    edx,edx   ; zero edx, as edx:eax gets divided by ebx...
div    ebx       ; ...now.

mov    [lcm],eax ; store the lcm into memory
于 2013-03-23T23:24:16.733 回答