6

举个简单的例子，假设我有一个数字列表，L我想找到第一个大于某个特定数字的元素X。我可以用这样的列表推导来做到这一点：

(mynode@127.0.0.1)24> L = [1, 2, 3, 4, 5, 6].              
[1,2,3,4,5,6]
(mynode@127.0.0.1)25> X = 2.5.
2.5
(mynode@127.0.0.1)26> [First | _] = [E || E <- L, E > X].  
[3,4,5,6]
(mynode@127.0.0.1)27> First.
3

但这似乎可能非常低效，因为列表可能很长，而且第一场比赛可能很早。所以我想知道是否a）是否有一种有效的方法可以在找到第一个匹配项后不评估列表中的其余元素？或者 b) 当它被编译时，Erlang 是否优化了其余的比较？

这就是我将如何实现我在 C 中寻找的东西：

int first_match(int* list, int length_of_list, float x){
    unsigned int i;
    for(i = 0; i < length_of_list, i++){
        if(x > list[i]){ return list[i]; } /* immediate return */
    }
    return 0.0; /* default value */
}
4

3 回答 3

15

好吧，像

firstmatch(YourList, Number) -> 
   case lists:dropwhile(fun(X) -> X =< Number end, YourList) of
     [] -> no_solution;
     [X | _] -> X
   end.
于 2012-09-30T01:17:02.527 回答
4

这是一个快速的解决方案：

first_greater([],_) -> undefined;
first_greater([H|_], Num) when H > Num -> H;
first_greater([_|T], Num) -> first_greater(T,Num).
于 2012-09-30T09:16:57.467 回答
4

这就是我能想到的。我仍然想知道是否有更好的答案和/或最简单的事情是否得到优化（我想得越多，我就越怀疑它）。

-module(lazy_first).

-export([first/3]).

first(L, Condition, Default) ->
  first(L, [], Condition, Default).

first([E | Rest], Acc, Condition, Default) ->
  case Condition(E) of
    true -> E;
    false -> first(Rest, [E | Acc], Condition, Default)
  end;

first([], _Acc, _Cond, Default) -> Default.

例子：

14> lazy_first:first([1, 2, 3, 4, 5], fun(E) -> E > 2.5 end, 0.0).
3
15> lazy_first:first([1, 2, 3, 4, 5], fun(E) -> E > 5.5 end, 0.0).
0.0

编辑

这是一个没有蓄能器的版本。

first([E | Rest], Condition, Default) ->
  case Condition(E) of
    true -> E;
    false -> first(Rest, Condition, Default)
  end;

first([], _Cond, Default) -> Default.
于 2012-09-29T23:37:40.607 回答