perl - 如何在 Perl 中搜索和替换文件中的字符串

Question

我的输入文件的内容如下所示：

abc\**def\ghi**\abc\!!!!!
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw
abc\**eg4/refw**\abc\f3

我需要将abc \ --------------\abc输入文件中的任何字符串替换为ABC\CBA.

我已经尝试过类似下面的方法来获取需要替换的字符串。但是当我需要使用搜索和替换时我卡住了：

my $string1 = qr/abc\W+([^a]+)/;
my $string2 = map{/$string1/ => " "} @input_file; # The string that needs to be replaced
my $string3 = 'ABC\CBA'  # String in that. I want it to replace to

s/$string2/$string3/g

我怎样才能解决这个问题？

Answer 1

perl -i -pe 's/this/that/g;'  file1

Answer 2

修复文件的单行：

perl -plwe 's/abc\\\K.*(?=\\abc)/ABC\\CBA/' input.txt > output.txt

或作为脚本：

use strict;
use warnings;

while (<DATA>) {
    s/abc\\\K.*(?=\\abc)/ABC\\CBA/;
    print;
}

__DATA__
abc\**def\ghi**\abc\!!!!!
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw
abc\**eg4/refw**\abc\f3

( \Kkeep) 转义序列意味着这些字符不会被删除。类似地，前瞻断言(?= ... )将保留匹配的那部分。我假设您只想更改两者之间的字符。

而不是\K一个可以使用后视断言：(?<=abc\\). 作为个人喜好，我\K改用了。

Answer 3

如果您不希望替换对默认变量进行操作，$_则必须使用=~运算符：

#!/usr/bin/perl
use warnings;
use strict;

my @input_file = split /\n/, <<'__EOF__';
abc\**def\ghi**\abc\!!!!!
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw
abc\**eg4/refw**\abc\f3
__EOF__

my $pattern = qr/abc\\.*\\abc/;       # pattern to be matched
my $string2 = join "\n", @input_file; # the string that need to be replaced
my $string3 = 'ABC\CBA';              # string i that i want it to replace to

$string2 =~ s/$pattern/$string3/g;
print $string2;

Answer 4

#!/usr/bin/perl
use strict;
use warnings;

open my $fh,"<", "tryit.txt" or die $!;

while (my $line = <$fh>) {
    $line =~ s/(abc\\)(.*?)(\\abc)/$1ABC\\CBA$3/;
    print $line;
}

给出以下输入数据。

abc\ABC\CBA\abc\!!!!!
abc\ABC\CBA\abc\df3gwddw
abc\ABC\CBA\abc\f3

Answer 5

要解决您对直接在文件中“就地”替换文本的评论，您可以将-i开关用于单行。在脚本中，您也许可以查看 using Tie::File，它允许对文件行作为数组中的（可变）元素进行读写访问。要复制 Mike/TLP 的答案：

#!/usr/bin/perl
use strict;
use warnings;

use Tie::File;

tie my @file, "Tie::File", "tryit.txt" or die $!;

# I think you have to use $_ here (done implicitly)
while (@file) {
    s/(abc\\)(.*?)(\\abc)/$1ABC\\CBA$3/;
    print;
}