1

我的任务是进行一些字符串操作，今天一定是我糟糕的一天，因为事实证明它比我预期的要困难。

我必须从第一列、第二列和第三列以及任何姓氏中取第一个、第二个和第三个名字的首字母

另外，我们需要保留标题。

这是现在的长名称示例：

C Chrysostomou 先生和 N Chrysostomou 先生和 A Chrysostomou 夫人

M Karseras 夫人和 P Hadjisoteriou 女士和 E Athanasiou 夫人

A Theodorou 夫人 & A Aristotelou 先生 & G Naziri 夫人 & M Karmiou L Vazanias 夫人 & G 夫人

Braithwaite 和 Helen West 夫人 L Vazanias 夫人和 G 夫人 Braithwaite 和夫人

海伦·韦斯特 Olympia Pieridou 夫人和 T 夫人和 M 先生、C 先生和 K 夫人

Michaelides JA Santamas 小姐和 MT Santama 夫人- Solomonides 和 Lida 夫人

Santama JA Santamas 小姐和 MT Santama 夫人- Solomonides 和 Lida 夫人

Santama Polydoros Polydorou 先生和 Maro Themistocleous 夫人和 Sylvia 夫人

Polydorou Themis 先生和 Androulla 夫人和 Nicholas 先生和 Vasso Gina 夫人

Demetriou SK Makkofaides 夫人和 Z Koullas 先生和 Y Koullas 夫人和 R 夫人

Kleopa G Zorzy 先生和 H Louca Zorzy 夫人和 S Stavropoulos 先生和 Y 夫人

Stavropoulos Mrs M Franceschina & Ms C Eugeniou & Ms OL Toumazides

T/a The Three Cupcakes Mr David & Mrs Eileen Nixon Dhnixon & Co. - Office Account

如您所见，这些可以被认为是 2 人甚至 3 人之间的联名银行账户。我们必须保留姓名，可能是先生、小姐、女士、博士、医生或 先生，以及名字和姓氏的首字母以及全姓，总数应少于 35 个字符！

所以，这是我在网上搜索后一直在尝试的：

=IF(LEN(TRIM(E:E))-LEN(SUBSTITUTE(TRIM(E:E)," ",""))>=1,MID(TRIM(E:E),FIND(" ",TRIM(E:E))+1,1),"")& " " &IF(LEN(TRIM(E:E))-LEN(SUBSTITUTE(TRIM(E:E)," ",""))>=2,MID(SUBSTITUTE(TRIM(E:E)," ","",1),FIND(" ",SUBSTITUTE(TRIM(E:E)," ","",1))+1,1),"")

得到首字母，但只有前两个

=RIGHT(J:J,LEN(J:J)-FIND(" ",J:J)+1)

获取姓氏，但无法正常工作。

我是在想这个，还是在想它？

我处理数据的最佳方法是什么？

谢谢菲利普

4

1 回答 1

1

这应该让你开始。

假设您的数据看起来像这样

在此处输入图像描述

将此代码粘贴到模块中。（注意：此代码未经广泛测试，但传达了信息）

Option Explicit

Sub Sample()
    Dim MyAr As Variant
    Dim FinalAr() As String, TmpAr() As String
    Dim ws As Worksheet
    Dim lrow As Long, i As Long, n As Long, j As Long

    '~~> Set this to the relevant sheet
    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        '~~> get last row of col A
        lrow = .Range("A" & .Rows.Count).End(xlUp).Row

        '~~> Store the values in an array
        MyAr = .Range("A1:A" & lrow)

        '~~> Loop through the array and split it on "&" and store it in another array
        For i = LBound(MyAr) To UBound(MyAr)
            If InStr(1, MyAr(i, 1), "&") Then
                TmpAr = Split(MyAr(i, 1), "&")

                For j = LBound(TmpAr) To UBound(TmpAr)
                    n = n + 1
                    ReDim Preserve FinalAr(n)
                    FinalAr(n) = Trim(TmpAr(j))
                Next j
            Else
                n = n + 1
                ReDim Preserve FinalAr(n)
                FinalAr(n) = Trim(MyAr(i, 1))
            End If
        Next i

        '~~> Past the outcome in Col B
        .Range("B1").Resize(UBound(FinalAr) + 1, 1).Value = Application.Transpose(FinalAr)

        '~~> Replace all mrs/mr etc
        .Columns(2).Replace What:="MRS", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False

        .Columns(2).Replace What:="MR", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False

        .Columns(2).Replace What:="MISS", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False

        '~~> Find Last Row of Col B
        lrow = .Range("B" & .Rows.Count).End(xlUp).Row

        '~~> Loop through col B and split the names
        For i = 2 To lrow
            If InStr(1, .Range("B" & i), " ") Then
                TmpAr = Split(Trim(.Range("B" & i)), " ")

                n = 1

                For j = LBound(TmpAr) To UBound(TmpAr)
                    .Range("B" & i).Offset(, n).Value = TmpAr(j)
                    n = n + 1
                Next
            Else
                .Range("C" & i).Value = .Range("B" & i).Value
            End If
        Next i
    End With
End Sub

结果（截图）

在此处输入图像描述

于 2013-04-16T12:16:50.677 回答