2

我制作了一个带有透明表单的小型 EXE，上面有一个 TImage。为了使我的表单透明，我使用以下代码：

Function TForm1.CombineRegions (FrmX , FrmY  :Integer;CtrlComp : TControl;Var RegHandle : THandle) : Boolean;

Var
CtrlHandle : THandle;
 CtrlLeft,
 CtrlTop,
 CtrlWidth,
 CtrlHt     : Integer;
begin
  Result := False;
  CtrlHandle := 0;
  FrmX := 0;
  FrmY := 0;
  Try
      CtrlLeft   := CtrlComp.Left;
      CtrlTop    := CtrlComp.Top;
      CtrlWidth  := CtrlComp.Width;
      CtrlHt     := CtrlComp.Height;

 Except
     Exit;
 End;

 Try
   FrmX:=0;
   FrmY:=0;
   FrmX := FrmX + CtrlLeft;
   FrmY := FrmY + CtrlTop;
   CtrlHandle := CreateRectRgn(FrmX, FrmY, FrmX + CtrlWidth, FrmY + CtrlHt) ;
   CombineRgn(RegHandle, RegHandle, CtrlHandle, RGN_OR) ;
Except
End;
End;

它所做的是首先使所有表单消失，然后根据我想要在表单上的哪些控件，我将调用上述函数并且只绘制该区域。现在我的 TImage 有一个图像，它有一些背景颜色。图片

如您所见，图像有一些背景。我希望绘制我的 TImage 以便只绘制里面的位图，而不是整个区域。可以做到吗？提前致谢。

4

2 回答 2

0

我有一个仅显示混合在屏幕上的 32 位 PNG 图像的启动表单，希望对您有所帮助。

unit SplashU;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, pngimage, ExtCtrls;

type
  TSplashForm = class(TForm)
    SplashImg: TImage;
  public
    procedure Execute;
  end;

var
  SplashForm: TSplashForm;

implementation

{$R *.dfm}

procedure TSplashForm.Execute;
var
  t: Cardinal;
  f: TBlendFunction;
  p: TPoint;
  z: TSize;
  s: DWORD;
  b: TBitmap;
  x, y:integer;
  a, d,c: PByteArray;
begin
s := GetWindowLongA(Handle, GWL_EXSTYLE);
if (s and WS_EX_LAYERED = 0) then
  SetWindowLong(Handle, GWL_EXSTYLE, s or WS_EX_LAYERED);

b := TBitmap.Create;
b.Width :=  SplashImg.Width;
b.Height :=  SplashImg.Height;
b.PixelFormat := pf32bit;
for y := SplashImg.Height - 1 downto 0 do
  begin
  a := (SplashImg.Picture.Graphic as TPNGObject).AlphaScanline[y];
  c := (SplashImg.Picture.Graphic as TPNGObject).Scanline[y];
  d := b.ScanLine[y];
  for x := 0 to SplashImg.Width - 1 do
    begin
    d^[x * 4 + 3] := a^[x];
    d^[x * 4] := MulDiv(c^[x * 3], a^[x], 255);
    d^[x * 4 + 1] := MulDiv(c^[x * 3 + 1], a^[x], 255);
    d^[x * 4 + 2] := MulDiv(c^[x * 3 + 2], a^[x], 255);
    end;
  end;

p := Point(0, 0);
z.cx := b.Width;
z.cy := b.Height;

f.BlendOp := AC_SRC_OVER;
f.BlendFlags := 0;
f.SourceConstantAlpha := 0;
f.AlphaFormat := AC_SRC_ALPHA;

Show;
t := 0;
while (f.SourceConstantAlpha < 255) do
  begin
  while (t = GetTickCount) do Sleep(25);
  t := GetTickCount;
  Inc(f.SourceConstantAlpha, (255 - f.SourceConstantAlpha) div 32 + 1);
  UpdateLayeredWindow(Handle, 0, nil, @z, b.Canvas.Handle, @p, 0, @f, ULW_ALPHA);
  end;
b.Free;
end;

end.
于 2012-08-08T10:41:53.577 回答
0

获得一个正常的形式，隐藏它的所有边缘/标题。将您的图像放在该表单上并将其与 alClient 对齐。在 for 循环中将表单的透明度 (TForm.AlphaBlendValue) 设置为 0 到 255。

伪代码：

procedure ShowSplashScreen;
begin
 frmSplash:= TfrmSplash.Create(NIL);
 frmSplash.imgSplash.Picture.LoadFromFile('Splash.png');
 frmSplash.AlphaBlendValue:= StartValue; // This is about 50
 frmSplash.CurrAlpha:= frmSplash.AlphaBlendValue;
 frmSplash.Increment:= 5;  
 frmSplash.Show;         
 frmSplash.FormStyle := fsStayOnTop;   
 frmSplash.Timer.Enabled:= TRUE;
end;

我将它与 PNG 图像（具有透明度）一起使用，它可以工作。

于 2022-01-04T20:20:39.643 回答