4

在我的 xslt 模板中，我有一个for-each声明。在那for-each我正在创造不同的条件。我希望有一个字符串类型的变量，该变量应包含将分配给的类属性<li>。

由于我是 xslt 的新手，请提供一些示例或如何实现我想做的事情。

这是我的一些代码，因此您可以看到我在做什么：

<xsl:if test="count($currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']) &gt; '0'">
    <xsl:for-each select="$currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']">
        <li><xsl:attribute name="class">
                topNavigLi
                page<xsl:number value="position()" format="1" />
                <xsl:if test="@nodeName='Network' ">
                    has_submenu network
                </xsl:if>
            </xsl:attribute>
            <xsl:if test="@id = $currentPage/@id">
                <xsl:attribute name="class">
                    current topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>
            <xsl:if test="position() = last()">
                <xsl:attribute name="class">
                    last topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>

            <xsl:if test="@id = $currentPage/@id and position() = last()">
                <xsl:attribute name="class">
                    current last topNavigLi
                    page<xsl:number value="position()" format="1" />
                </xsl:attribute>
            </xsl:if>

拥有一个变量并在进行测试时连接到它会更加优雅。我试过这样但什么也没返回。

<xsl:variable name="li_class" select="page"> </xsl:variable>

<xsl:attribute name="class">
    <xsl:value-of select="li_class" /> 
</xsl:attribute>
4

4 回答 4

8

这是一个执行我认为您要求的示例：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <xsl:copy>
       <xsl:apply-templates/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="num">
  <xsl:variable name="vResult">

    <xsl:if test=". mod 2 = 0">Even </xsl:if>
    <xsl:if test=". mod 3 = 0"> mult3</xsl:if>
    <xsl:if test="not(. mod 2 = 0 or . mod 3 = 0)">none</xsl:if>
  </xsl:variable>

  <xsl:variable name="vnormResults" select="normalize-space($vResult)"/>

  <num tests="{$vnormResults}">
   <xsl:value-of select="."/>
  </num>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

结果是：

<nums>
   <num tests="none">01</num>
   <num tests="Even">02</num>
   <num tests="mult3">03</num>
   <num tests="Even">04</num>
   <num tests="none">05</num>
   <num tests="Even mult3">06</num>
   <num tests="none">07</num>
   <num tests="Even">08</num>
   <num tests="mult3">09</num>
   <num tests="Even">10</num>
</nums>
于 2012-07-24T12:18:46.727 回答
2

我假设你想把像'page1'这样的字符串放在一个变量中并重新使用？

如果是这样，请尝试...

           <xsl:for-each select="$currentPage/ancestor-or-self::* [@level=$level]/[@isDoc and string(umbracoNaviHide) != '1']">
                <xsl:variable name="page-num" select="concat('page',position())" /> 
                <li><xsl:attribute name="class">
                        topNavigLi
                        <xsl:value-of select="$page-num" />
                        <xsl:if test="@nodeName='Network' ">
                            has_submenu network
                        </xsl:if>
                    </xsl:attribute>
                    <xsl:if test="@id = $currentPage/@id">
                        <xsl:attribute name="class">
                            current topNavigLi
                            <xsl:value-of select="$page-num" />
                        </xsl:attribute>
                    </xsl:if>
                    <xsl:if test="position() = last()">
                        <xsl:attribute name="class">
                            last topNavigLi
                            page<xsl:number value="position()" format="1" />
                        </xsl:attribute>
                    </xsl:if>

                    <xsl:if test="@id = $currentPage/@id and position() = last()">
                        <xsl:attribute name="class">
                            current last topNavigLi
                            <xsl:value-of select="$page-num" />
                        </xsl:attribute>
                    </xsl:if>

在 XSLT 1.0 中，定义变量的语法在此处，对于 XSLT 2.0，它在此处。要访问 XPATH 上下文中的变量，请在名称前加上美元符号 ($)。

于 2012-07-24T12:10:38.703 回答
2

$像这样（带符号）在 XSLT 中获取变量的值：

<xsl:variable name="li_class" select="page"> </xsl:variable>

<xsl:attribute name="class">
    <xsl:value-of select="$li_class" /> 
</xsl:attribute>
于 2012-07-24T12:35:16.273 回答
2

在同时阅读之后，我发现（但我主要知道的事情）：

您需要修改 an 的事实表明您没有考虑 XSLT。

XSLT 是一种函数式编程语言，除其他外，这意味着无法更改变量。根据定义，函数式编程语言中的变量是不可变的。资料来源：http ://social.msdn.microsoft.com/Forums/eu/xmlandnetfx/thread/2bf7d238-92d2-4453-a683-4bfb0c667795

所以我稍微改变了我的逻辑：我将所有条件都放在 xsl 属性中，如下所示：

 <xsl:if test="count($currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']) &gt; '0'">
            <xsl:for-each select="$currentPage/ancestor-or-self::* [@level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']">
                <li>
                    <xsl:attribute name="class">
                        page topNavigLi page<xsl:number value="position()" format="1" />
                        <xsl:if test="@id = $currentPage/@id">
                            current 
                        </xsl:if>
                        <xsl:if test="position() = last()">
                            last
                        </xsl:if>
                        <xsl:if test="@nodeName='Network' ">
                            has_submenu network
                        </xsl:if>
                    </xsl:attribute>

所以不需要额外的临时变量。

于 2012-07-24T12:59:47.117 回答