delphi - 为什么编译器会跳过分配变量

Question

我有以下程序：

procedure GetDegree(const num : DWORD ; var degree : DWORD ; min ,sec : Extended);
begin
  degree := num div (500*60*60);
  min := num div (500*60) - degree *60;
  sec := num/500 - min *60 - degree *60*60;
end;

在度变量被分配后，调试器跳到过程的末尾。这是为什么？

Answer 1

这是一个优化。变量min和sec通过值传递。这意味着调用者看不到对它们的修改，并且对这个过程是私有的。因此编译器可以确定分配给它们是没有意义的。分配给变量的值永远无法读取。因此编译器选择节省时间并跳过分配。我希望您打算像这样声明程序：

procedure GetDegree(const num: DWORD; var degree: DWORD; var min, sec: Extended);

正如我在上一个问题中所说，使用Extended. 使用其中一种标准浮点类型会更好，Single或者Double. 甚至使用Real映射到的泛型Double。

此外，您已声明min为浮点类型，但计算计算的是整数。在这方面，我对您上一个问题的回答是相当准确的。

---

我建议您创建一个记录来保存这些值。传递三个单独的变量会使您的函数接口非常混乱并破坏封装。这三个值只有在整体考虑时才有意义。

type
  TGlobalCoordinate = record
    Degrees: Integer;
    Minutes: Integer;
    Seconds: Real;
  end;

function LongLatToGlobalCoordinate(const LongLat: DWORD): TGlobalCoordinate;
begin
  Result.Degrees := LongLat div (500*60*60);
  Result.Minutes := LongLat div (500*60) - Result.Degrees*60;
  Result.Seconds := LongLat/500 - Result.Minutes*60 - Result.Degrees*60*60;
end;

function GlobalCoordinateToLongLat(const Coord: TGlobalCoordinate): DWORD;
begin
  Result := Round(500*(Coord.Seconds + Coord.Minutes*60 + Coord.Degrees*60*60));
end;