3

我在 SQL Server 2012 ACOS 函数中遇到了这个错误：

declare @lat1 decimal(12,10), @lon1 decimal(12,10), @lat2 decimal(12,10), @lon2 decimal(12,10)
declare @dist float

select @lat1=51.1790825000, @lon1= 4.1590020000, @lat2= 51.1790825000, @lon2= 4.1590020000  
set @dist = SIN(RADIANS(@lat1)) * SIN(RADIANS(@lat2)) + COS(RADIANS(@lat1)) * COS(RADIANS(@lat2)) * COS(RADIANS(@lon1 - @lon2))

print @dist
print ACOS(1)
print ACOS(@dist)

最后一个打印函数给出“发生了无效的浮点操作”。这在 SQL Server 2008 中运行良好

弗拉德

4

4 回答 4

3

看起来您正在尝试计算地球上两点之间的距离。让您的生活更轻松并使用内置的地理类型。

DECLARE @lat1 DECIMAL(12, 10) ,
    @lon1 DECIMAL(12, 10) ,
    @lat2 DECIMAL(12, 10) ,
    @lon2 DECIMAL(12, 10)
DECLARE @dist FLOAT

SELECT  @lat1 = 51.1790825000 ,
        @lon1 = 4.1590020000 ,
        @lat2 = 51.1790825000 ,
        @lon2 = 4.1590020000

DECLARE @p1 GEOGRAPHY = GEOGRAPHY::Point(@lat1, @lon1, 4326) ,
    @p2 GEOGRAPHY = GEOGRAPHY::Point(@lat2, @lon2, 4326)

SELECT  @dist = @p1.STDistance(@p2)
于 2012-04-17T14:48:00.513 回答
1

acos() 函数的浮点值参数必须在 -1 到 1 范围之间。因此

FUNCTION [dbo].[Calculate_Distance]  
(  
@Lat1 float, @Long1 float, @Lat2 float, @Long2 float  
)  
RETURNS float  
AS  
BEGIN  

    DECLARE @acosValue float     
    DECLARE @R float  
    SET @R = 3958.7558657440545 -- mi       
    DECLARE @Distance float  
    Set @acosValue= cos( radians(@Lat1) ) * cos( radians( @Lat2 ) ) * cos( radians( @Long2 ) - radians(@Long1) ) + sin( radians(@Lat1) ) * sin( radians( @Lat2 ) ) ;
    IF @acosValue>1.0 
    Begin
    Set @acosValue=1.0;
     End
    IF @acosValue<-1.0 
    Begin
    Set @acosValue=-1.0;
     End

    SET @Distance = acos(@acosValue)
     * @R;  

    RETURN @Distance  

END 
GO

尝试这个

于 2012-08-13T11:24:25.953 回答
1

利用

print ACOS(CASE WHEN @dist > 1 THEN 1 ELSE @dist END)

@dist是一种float数据类型，实际上略多于1由于舍入问题，如下所示。

SELECT CAST(@dist AS BINARY(8)) AS [@dist], 
       CAST(CAST(1 AS FLOAT) AS BINARY(8)) AS [1]

退货

@dist              1
------------------ ------------------
0x010000000000F03F 0x000000000000F03F

010000000000F03F在此处插入IEEE 转换器表明这大致1.0000000000000002220446049250313080847263可以从下面验证（返回Y）

SELECT 
     CASE WHEN @dist between 1.0000000000000002220446049250313080847 AND 
                             1.0000000000000002220446049250313080848 
     THEN 'Y' ELSE 'N' END
于 2012-04-17T12:38:17.890 回答
0

正如其他答案所述，您有一个浮点问题，它会根据不同的 CPU 架构以不同的方式呈现。但是，有一个简单的单线可以解决您的问题：

declare @dist float需要更改为declare @dist decimal(12, 10).

于 2013-12-31T16:43:48.547 回答