perl - 即使@array 包含与 LIST 相同的元素，为什么 @array ~~ LIST 返回 false？

Question

我有

@a = (1,2,3); print (@a ~~ (1,2,3))

和

@a = (1,2,3); print (@a == (1,2,3))

第一个是我希望工作的那个，但它不打印任何东西。第二个确实打印 1。

为什么？智能匹配运算符不~~应该在 的情况下匹配@a ~~ (1,2,3)吗？

Answer 1

稍等一下，让我们考虑稍微不同的

\@a ~~ (1,2,3)

~~在标量上下文中评估其参数，因此上述内容与

scalar(\@a) ~~ scalar(1,2,3)

• \@a（在任何情况下）返回对@a.
• 1, 2, 3在标量上下文中类似于do { 1; 2; 3 }，返回3。

所以减去几个警告*，以上等价于

\@a ~~ 3

你真正想要的是

\@a ~~ do { my @temp = (1,2,3); \@temp }

可以缩短为

\@a ~~ [ 1,2,3 ]

最后， 的魔法~~允许\@a写成@a，因此可以进一步缩短为

@a ~~ [ 1,2,3 ]

* — 始终使用use strict; use warnings;！

Answer 2

如果您在右侧使用数组或数组引用，智能匹配会尝试执行我认为您所期望的操作 - 但不是列表。

$ perl -E '@a = (1, 2, 3); say (@a ~~ (1, 2, 3))'

$ perl -E '@a = (1, 2, 3); say ((1, 2, 3) ~~ @a)' # also misguided, but different
1
$ perl -E '@a = (1, 2, 3); say (@a ~~ [1, 2, 3])'
1

Answer 3

先来看看列表和数组有什么区别？在 perlfaq 中。它特别向您展示了您选择的值是如何错误的。

您也可以先写出您期望每个工作或不工作的原因，以便我们纠正您的期望。为什么你认为你会得到你预期的结果？

至于智能匹配位，没有规则ARRAY ~~ LIST。智能匹配仅适用于perlsyn表中列举的配对。这将迫使它成为其中一对。

当您遇到这些问题时，请尝试更多情况：

#!perl
use v5.10.1;
use strict;
use warnings;

my @a = (1,2,3);
say "\@a is @a";
say "\@a ~~ (1,2,3) is ", try( @a ~~ (1,2,3) );
say "\@a ~~ [1,2,3] is ", try( @a ~~ [1,2,3] );
say "\@a ~~ 3 is ", try( @a ~~ 3 );
say "3 ~~ \@a is ", try( 3 ~~ @a );

say '';

my @b = (4,5,6);
say "\@b is @b";
say "\@b ~~ (4,5,6) is ", try( @b ~~ (4,5,6) );
say "\@b ~~ [4,5,6] is ", try( @b ~~ [4,5,6] );
say "\@b ~~ 3 is ", try( @b ~~ 3 );
say "3 ~~ \@b is ", try( 3 ~~ @b );

say '';
say "\@b ~~ \@a is ", try( @b ~~ @a );

sub try { $_[0] || 0 }

各种案例的输出是您误读文档的线索：

Useless use of a constant (2) in void context at test.pl line 8.
Useless use of a constant (4) in void context at test.pl line 17.
Useless use of a constant (5) in void context at test.pl line 17.
@a is 1 2 3
@a ~~ (1,2,3) is 0
@a ~~ [1,2,3] is 1
@a ~~ 3 is 0
3 ~~ @a is 1

@b is 4 5 6
@b ~~ (4,5,6) is 0
@b ~~ [4,5,6] is 1
@b ~~ 3 is 0
3 ~~ @b is 0

@b ~~ @a is 0