5

是否可以强制 zsh 在使用时回显所有别名引用的实际命令？

例如，假设我设置了以下别名：

# List direcory contents
alias lsa='ls -lah'
alias l='ls -la'
alias ll='ls -l'

当我执行它们时，我希望看到它们中的每一个都打印出实际执行的命令。例如，我希望看到以下内容：

$ ll
executing: 'ls -l'
total 0
-rw-r--r--  1 person  staff  0 Feb 15 13:46 cool.txt
-rw-r--r--  1 person  staff  0 Feb 15 13:46 sweet.html
-rw-r--r--  1 person  staff  0 Feb 15 13:46 test.md

而不是以下内容：

$ ll
total 0
-rw-r--r--  1 person  staff  0 Feb 15 13:46 cool.txt
-rw-r--r--  1 person  staff  0 Feb 15 13:46 sweet.html
-rw-r--r--  1 person  staff  0 Feb 15 13:46 test.md

是否有一个命令可以添加到我的 zshrc 以使所有别名都发生这种情况？我宁愿不必修改每个别名。

4

2 回答 2

9

如果别名是命令行上出现的第一个单词，您可以显示别名，您可以尝试将以下代码放入您的 .zshrc 中：

_-accept-line () {
    emulate -L zsh
    local -a WORDS
    WORDS=( ${(z)BUFFER} )
    # Unfortunately ${${(z)BUFFER}[1]} works only for at least two words,
    # thus I had to use additional variable WORDS here.
    local -r FIRSTWORD=${WORDS[1]}
    local -r GREEN=$'\e[32m' RESET_COLORS=$'\e[0m'
    [[ "$(whence -w $FIRSTWORD 2>/dev/null)" == "${FIRSTWORD}: alias" ]] &&
        echo -nE $'\n'"${GREEN}Executing $(whence $FIRSTWORD)${RESET_COLORS}"
    zle .accept-line
}
zle -N accept-line _-accept-line

描述（略过一些琐碎的事情）：

emulate -L zsh # Reset some options to zsh defaults (locally).
               # Makes function immune to user setup.

local -a WORDS # Declare WORDS as an array local to function

${(z)VARNAME}  # Split VARNAME using command-line parser.
               # Things like “"first word" "second word"” get split into 2 words:
               # “"first word"” “"second word"”

$BUFFER        # Variable containing the whole command-line. Can be modified

local -r V     # Declare variable “V” as read-only

$'\e[32m'      # Escape code for green foreground color in most terminals
$'\e[0m'       # Sequence that being echoed to terminal clears out color information

whence -w cmd  # Display type of the command in format “cmd: type”
whence cmd     # If “cmd” is an alias, then this command outputs alias value

zle .accept-line # Call internal zle “accept-line” widget. This must be done or 
               # every command will turn to no-op. You can, of course, replace
               # this with “eval $BUFFER” but I can’t say what will break in this case

zle -N accept-line _-accept-line # Associate widget “accept-line” with function
               # “_-accept-line”. This makes this function responsible for accepting
               # lines.

man zshbuiltins( emulate, whence, local), man zshzle( zle, $BUFFER), man zshparam( )中的更多信息${(z)}。

于 2012-02-15T21:56:11.243 回答
0

感谢ZyX。我修改了他的答案，使其也适用于函数。这里是;

_-accept-line () {
    emulate -L zsh
    local -a WORDS
    WORDS=( ${(z)BUFFER} )
    # Unfortunately ${${(z)BUFFER}[1]} works only for at least two words,
    # thus I had to use additional variable WORDS here.
    local -r FIRSTWORD=${WORDS[1]}
    local -r GREEN=$'\e[32m' RESET_COLORS=$'\e[0m'
    [[ "$(whence -w $FIRSTWORD 2>/dev/null)" == "${FIRSTWORD}: alias" ]] &&
        echo -nE $'\n'"${GREEN}Executing -> ${$(which $FIRSTWORD)//"$FIRSTWORD: aliased to "/""}${RESET_COLORS}"
    [[ "$(whence -w $FIRSTWORD 2>/dev/null)" == "${FIRSTWORD}: function" ]] &&
        echo -nE $'\n'"${GREEN}Executing -> ${$(which $FIRSTWORD)//"$FIRSTWORD () {
    "/""}${RESET_COLORS}"
    zle .accept-line
}
zle -N accept-line _-accept-line

PS：它是在短时间内开发的。当然，它可以改进。

于 2020-05-19T11:34:57.987 回答