4

我有一个广泛使用 wstring 的库。我需要使用 NSLog 输出更改和外部数据有没有一种简单的方法（不太昂贵）使用中间函数输出 wstring。使用 va_list 将每个 wstring 转换为 NSString 是我现在能想到的唯一方法。

编辑：更精确。我有一个多平台库。我添加了一个日志记录宏 MYLog。

编辑 我必须从 C++ 调用我的 MYLog，而此时我无法访问 Objective-C。所以问题是在调用 MYLog 之前我无法转换 std::wstring。

通过 MYLog 我希望能够使用 NSLog 或如下中间体：

MYLog("Received %ls(%d) from user %ls %ls cp: %ls /nRAW:/t%ls",
       &d.name, d.id, &d.user.firstName, &d.user.lastName,
       &d.caption, &d.rawText);

在这里（最初来自这里）我发现了对 NSString 的一个很好的补充：

@interface NSString (cppstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
+(NSString*) stringWithstring:(const std::string&)string;
-(std::wstring) getwstring;
-(std::string) getstring;
@end


@implementation NSString (cppstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t];
    return result;
}

+(NSString*) stringWithstring:(const std::string&)s
{
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}

-(std::string) getstring
{
    return [self UTF8String];
}

@end

在不浪费太多时间（我的）的情况下，我所能想到的就是创建一个由我的 MYLog 调用的中间函数：

#define LAD(data) [logString appendFormat:[NSString stringWithFormat:@"%%%@", c], data]
#define LAP(type) LAD(va_arg(listPointer, type))

void MyLogImplementation(NSString* message, ...)
{
NSMutableString* logString = [[NSMutableString alloc] init];

    va_list listPointer;
    va_start(listPointer, message);

NSArray* lmc = [message componentsSeparatedByString:@"%"];

int counter = 0;
//NSLog(@"there are %d components in %@.", [lmc count], message);
BOOL ignoreNext = NO;
for (NSString* c in lmc)
{
    //NSLog(@"Testing %@", c);

    if (ignoreNext)
    {
        [logString appendFormat:@"%%%@", c];
        ignoreNext = NO;
    }
    if (0 == [c length])
    {
        ignoreNext = !ignoreNext;
    }
    else if (0 == counter && '%' != [message characterAtIndex:0] )
    {
        [logString appendFormat:@"%@", c];
    }
    else 
    {
        switch ([c characterAtIndex:0])
        {
            case 'd':
            case 'i':
                LAP(int);
                break;

            case 'X':
            case 'x':
                LAP(int);
                break;

            case '@':
                LAP(NSObject*);
                break;

            case 'f':
                LAP(double);
                break;

            case 'c':
                LAP(char);
                break;

            case 'l':
                switch ([c characterAtIndex:1])
            {
                case 's':
                {
                    std::wstring* str = va_arg(listPointer, std::wstring*);
                    NSString* nstr = [NSString stringWithwstring:str];

                    [logString appendFormat:@"%@", nstr];

                    [nstr release];
                    if (2 < [c length])
                    {
                        [logString appendString:[c substringFromIndex:2]];
                    }
                }
                    break;
            }
                break;
            default:
                [logString appendFormat:[NSString stringWithFormat:@"%%%@", c]];

        }
    }
    ++counter;
}


    NSLog(@"%@", logString);
[logString release];
    va_end(listPointer);
}

但这——在我看来——效率很低。有没有更好的方法来实现我正在做的事情？我知道我可以简单地将其转换为：

NSLog(@"Received %@(%d) from user %@ %@ cp: %@ /nRAW:/t%@",
       [NSString stringWithwstring:d.name], d.id,
       [NSString stringWithwstring:d.user.firstName],
       [NSString stringWithwstring:d.user.lastName],
       [NSString stringWithwstring:d.caption],
       [NSString stringWithwstring:d.rawText]);

问题就会得到解决。但我会失去多平台优势......我猜。

4

2 回答 2

4

您可以转换为 NSString 并记录它。这是取自此处的 NSString 类别。不知道效果如何，但看起来很明智......

@interface NSString (wstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
-(std::wstring) getwstring;
@end

@implementation NSString (wstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t =
CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t =
CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t] autorelease];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}

@end
于 2011-11-26T12:40:02.440 回答
1

也许如果您使用 CoreFoundation 将其转换为 CFStringRef 然后将其传递给 CFLog(..) 或将其转换为 NSString* （免费桥接）并使用 NSLog(...)

CFStrings 位于 CoreFoundation 中，这是一个 C 级 API，因此应该可以从非 objc 领域调用。

<CoreFoundation/CFString.h>包含CFStringCreateWithBytes(...)或可能CFStringCreateWithCString(...)并传入适当的CFStringEncoding

于 2011-11-27T23:25:43.240 回答