hex - 在 MIPS 中将十六进制字符转换为十进制等效值

Question

如何获取单个 ASCII 字符并将其转换为 MIP 中的十进制等效值？

我是否只需要有一些条件才能从 ascii 代码中减去一定数量以使其成为十进制表示形式？

Answer 1

这是 Pax 所写内容的简单实现（它假设十六进制数字 - A 到 F 始终为大写）

文件 hextodec.c

#include <stdio.h>

/*
*Converts an ASCII char to its decimal equivalent.
*Returns -1 on error.
*
*/
extern int hextodec(char* c);

int main(int argc,char **argv){
        int i=0;
        char digits[]={'0','1','2','3','4','5','6','7','8','9','A','B','C','D','F'};

        for (;i<16;i++){
                printf("%c\t%d\n",digits[i],hextodec(digits+i));
        }
        return 0;
}

文件 hextodec.S

#include <mips/regdef.h>

/* int hextodec(char* c) 
 *  first (and only) argument is set in register a0.
 *  return value is set in register v0.
 *  function calling convention is ignored.
 */
        .text
        .globl hextodec
        .align 2
        .ent hextodec


hextodec:

        lbu     t0,0(a0)        #load byte from argument

        li      t1,0X30
        li      t2,0x39

        andi    t1,t1,0x000000ff #Cast to word for comparison.
        andi    t2,t2,0x000000ff

        bltu    t0,t1,ERROR     #error if lower than 0x30
        bgt     t0,t2,dohex     #if greater than 0x39, test for A -F

        addiu   t0,t0,-0x30     #OK, char between 48 and 55. Subtract 48.
        b       return

dohex:  li      t1,0x41
        li      t2,0x46

        andi   t1,t1,0x000000ff #Cast to word for comparison.
        andi   t2,t2,0x000000ff

        /*is byte is between 65 and 70?*/

        bltu    t0,t1,ERROR     #error if lower than 0x41
        bgt     t0,t2,ERROR     #error if greater than 0x46

ishex:  addiu   t0,t0,-0x37     #subtract 55 from hex char ('A'- 'F')
        b       return

ERROR:  addiu   t0,zero,-1      #return -1.

return: move    v0,t0           #move return value to register v0

        jr      ra
        .end    hextodec

测试运行

root@:~/stackoverflow# ./hextodec 
0       0
1       1
2       2
3       3
4       4
5       5
6       6
7       7
8       8
9       9
A       10
B       11
C       12
D       13
E       14
F       15
root@:~/stackoverflow# 

Answer 2

应检查单个十六进制字符是否在范围内

• “0”到“9”（48 到 57），
• “A”到“F”（65 到 70），或
• “a”到“f”（97 到 102）。

其他任何事情都是错误。如果它确实属于这些范围之一，请执行以下操作：

• 减去 48（将“0”-“9”降为 0-9）。
• 如果它仍然大于 9，则减去 7（将 'A'-'F' 降低到 10-15）。
• 如果它仍然大于 15，则减去 32（将 'a'-'f' 降低到 10-15）。

如果您确定非十进制数字的字符始终为大写，则可以跳过上面每个列表中的第三步，但不需要很多额外的代码即可。

Answer 3

是的，从 ASCII 值中减去 48 可能是最简单的。