6

尝试使用带有 Beta 边际的内置 copula 分布（Clayton、Frank、Gumbel）为两个因随机变量之和的分位数创建一个表。尝试NProbability并FindRoot使用各种方法 - 不够快。我需要探索的 copula-marginal 组合的一个例子如下：

nProbClayton[t_?NumericQ, c_?NumericQ] := 
        NProbability[  x + y <= t, {x, y}  \[Distributed]    
               CopulaDistribution[{"Clayton", c}, {BetaDistribution[8, 2], 
                                                   BetaDistribution[8, 2]}]]

对于使用数字概率的单一评估

nProbClayton[1.9, 1/10] // Timing // Quiet

我明白了

{4.914, 0.939718}

在 Vista 64 位 Core2 Duo T9600 2.80GHz 机器上 (MMA 8.0.4)

要获得总和的分位数，请使用

FindRoot[nProbClayton[q, 1/10] == 1/100, {q, 1, 0, 2}// Timing // Quiet

用各种方法

( `Method -> Automatic`, `Method -> "Brent"`, `Method -> "Secant"` )

大约需要一分钟才能找到一个分位数：时间是

{48.781, {q -> 0.918646}}
{50.045, {q -> 0.918646}}
{65.396, {q -> 0.918646}}

对于其他 copula-marginal 组合，时间稍好一些。

需要：任何改善计时的技巧/方法。

4

1 回答 1

7

带参数的 Clayton-Pareto copula 的 CDFc可以根据下式计算

cdf[c_] := Module[{c1 = CDF[BetaDistribution[8, 2]]}, 
   (c1[#1]^(-1/c) + c1[#2]^(-1/c) - 1)^(-c) &]

那么是和cdf[c][t1,t2]的概率。这意味着您可以根据x<=t1y<=t2x+y<=t

prob[t_?NumericQ, c_?NumericQ] := 
   NIntegrate[Derivative[1, 0][cdf[c]][x, t - x], {x, 0, t}]

我在我的机器上得到的时间是

prob[1.9, .1] // Timing

(* ==> {0.087518, 0.939825} *)

请注意，我得到的概率值与原始帖子中的概率值不同。但是，运行nProbClayton[1.9,0.1]会产生关于缓慢收敛的警告，这可能意味着原始帖子中的结果已关闭。此外，如果我更改x+y<=t为x+y>t的原始定义nProbClayton并计算，1-nProbClayton[1.9,0.1]我会得到0.939825（没有警告），这与上面的结果相同。

对于我得到的总和的分位数

FindRoot[prob[q, .1] == .01, {q, 1, 0, 2}] // Timing

(* ==> {1.19123, {q -> 0.912486}} *)

同样，我得到的结果与原始帖子中的结果不同，但与之前类似，更改x+y<=t为x+y>t和计算FindRoot[nProbClayton[q, 1/10] == 1-1/100, {q, 1, 0, 2}]返回与上述相同的值q。

于 2011-11-12T16:01:27.917 回答