2

我为一种语言编写了一个语法，现在我想处理一些语法糖结构，因为我正在考虑编写一个模板翻译器。

问题是我希望我的模板语法只翻译该语言的一些结构，其余部分保持原样。

例如：

我有这个作为输入：

class Main { 
   int a[10];
}

我想把它翻译成类似的东西：

class Main { 
   Array a = new Array(10);
}

理想情况下，我想在 ANTLR 中做一些这样的想法

grammer Translator
options { output=template;}

    decl 
         : TYPE  ID '[' INT ']' -> template(name = {$ID.text}, size ={$INT.text}) 
              "Array <name> = new Array(<size>);

我希望它保留与规则 decl 不匹配的其余输入。

在不编写语言的完整语法的情况下，如何在 ANTLR 中实现这一点？

4

1 回答 1

2

我会简单地在解析器语法中处理这些事情。

假设您正在解析器语法中构建 AST，我想您将有一个规则来解析输入，如下所示Array a = new Array(10);：

decl
  :  TYPE ID '=' expr ';' -> ^(DECL TYPE ID expr)
  ;

expr最终匹配term这样的地方：

term
  :  NUMBER
  |  'new' ID '(' (expr (',' expr)*)? ')' -> ^('new' ID expr*)
  |  ...
  ;

为了解释你的简写声明int a[10];，你所要做的就是decl像这样展开：

decl
  :  TYPE ID '=' expr     ';' -> ^(DECL TYPE    ID expr)
  |  TYPE ID '[' expr ']' ';' -> ^(DECL 'Array' ID ^(NEW ARRAY expr))
  ;

这会将输入重写int a[10];为以下 AST：

在此处输入图像描述

这与为 input 创建的 AST 完全相同Array a = new Array(10);。

编辑

这是一个小的工作演示：

grammar T;

options {
  output=AST;
}

tokens {
  ROOT;
  DECL;
  NEW='new';
  INT='int';
  ARRAY='Array';
}

parse
  :  decl+ EOF -> ^(ROOT decl+)
  ;

decl
  :  type ID '=' expr     ';' -> ^(DECL type  ID expr)
  |  type ID '[' expr ']' ';' -> ^(DECL ARRAY ID ^(NEW ARRAY expr))
  ;

expr
  :  Number
  |  NEW type '(' (expr (',' expr)*)? ')' -> ^(NEW ID expr*)
  ;

type
  :  INT
  |  ARRAY
  |  ID
  ;

ID     : ('a'..'z' | 'A'..'Z')+;
Number : '0'..'9'+;
Space  : (' ' | '\t' | '\r' | '\n') {skip();};

可以用类测试：

import org.antlr.runtime.*;
import org.antlr.runtime.tree.*;
import org.antlr.stringtemplate.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String src = "Array a = new Array(10); int a[10];";
    TLexer lexer = new TLexer(new ANTLRStringStream(src));
    TParser parser = new TParser(new CommonTokenStream(lexer));
    CommonTree tree = (CommonTree)parser.parse().getTree();
    DOTTreeGenerator gen = new DOTTreeGenerator();
    StringTemplate st = gen.toDOT(tree);
    System.out.println(st);
  }
}
于 2011-11-03T18:34:28.913 回答