delphi - 如何使用 RTTI 区分 TDateTime 属性和 Double 属性？

Question

使用 Delphi 2010 中的 RTTI 系统，有没有办法找出属性是否为 TDateTime？每当我回调 asVariant 以及检查属性类型时，它目前都将其视为双精度。这是因为它只能看到基本类型吗？（TDateTime = 双倍）

Answer 1

尝试检查的Name属性TRttiProperty.PropertyType

我没有 Delphi 2010，但这适用于 XE。

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Classes,
  Rtti;

type
  TMyClass =class
  private
    FDate: TDateTime;
    FProp: Integer;
    FDate2: TDateTime;
    FDate1: TDateTime;
  public
   property Date1 : TDateTime read FDate1  Write FDate1;
   property Prop : Integer read FProp  Write FProp;
   property Date2 : TDateTime read FDate2  Write FDate2;
  end;

var
 ctx : TRttiContext;
 t :  TRttiType;
 p :  TRttiProperty;
begin
 ctx := TRttiContext.Create;
 try
   t := ctx.GetType(TMyClass.ClassInfo);
   for p in  t.GetProperties do
    if CompareText('TDateTime',p.PropertyType.Name)=0 then
     Writeln(Format('the property %s is %s',[p.Name,p.PropertyType.Name]));
 finally
   ctx.Free;
 end;
  Readln;
end.

此代码返回

the property Date1 is TDateTime
the property Date2 is TDateTime

Answer 2

定义类型的关键点是类型指令。这两个定义不同：

Type
  TDateTime = Double; // here p.PropertyType.Name returns Double

but

Type
  TDateTime = type Double; // here p.PropertyType.Name returns TDateTime

or 

Type
  u8 = type Byte; // here p.PropertyType.Name returns u8

but

Type
  u8 = Byte; // here p.PropertyType.Name returns Byte !