7

所以我想要一种设置事件的方法，这样我就可以在不创建闭包\内存泄漏的情况下传递数据。据我所知：

package com.events {
    import flash.events.Event;

    public class CustomEvent extends Event {
        public static const REMOVED_FROM_STAGE:String = "removedFromStage";
        public var data:*;

        public function CustomEvent(type:String, customData:*=null, bubbles:Boolean=false, cancelable:Boolean=false) {
            super(type, bubbles, cancelable);
            this.data = customData;
        }

        public override function clone():Event {
            return new CustomEvent(type, data, bubbles, cancelable);
        }

        public override function toString():String {
            return formatToString("CustomEvent", "type", "data", "bubbles", "cancelable", "eventPhase");
        }
    }
}

这让我有以下行为：

function testme(e:Event) {
    trace(e); 
}

test_mc.addEventListener(CustomEvent.REMOVED_FROM_STAGE, testme);
test_mc.dispatchEvent(new CustomEvent(CustomEvent.REMOVED_FROM_STAGE, 42));
//Traces [CustomEvent type="removedFromStage" data=42 bubbles=false cancelable=false eventPhase=2]
removeChild(test_mc);
//Traces [Event type="removedFromStage" bubbles=false cancelable=false eventPhase=2]

我的目标是获取我想要传递的自定义数据，以便从事件闪光触发中传递，而不仅仅是我触发的那个。例如，如果我想传递一个movieclip 和一个loader.COMPLETE 事件来放入生成的位图怎么办？

4

2 回答 2

4

您扩展了 Event 类以使用额外的数据进行分派，现在如果您希望 Loader 类分派您的自定义事件类型，请扩展 Loader 类来执行此操作（或您想要执行此操作的任何其他类）。在这个例子中，我将用这个功能覆盖 URLLoader（因为 Loader 实际上从它的 contentLoaderInfo 调度事件，它需要两个被覆盖的类，我只是想保持简单）


package com.net
{
    import flash.net.URLLoader;
    import flash.events.Event;

    import com.events.CustomEvent;

    public class CustomLoader extends URLLoader
    {
        // URLLoader already has a data property, so I used extraData
        public var extraData:*;

        override public function dispatchEvent(event: Event) : Boolean
        {
            var customEvent: CustomEvent = new CustomEvent(event.type, extraData, event.bubbles, event.cancelable);
            return super.dispatchEvent(customEvent);
        }
    }
}

现在要将其与您的 CustomEvent 类一起使用，请在您的 .fla 中尝试此代码


import com.net.CustomLoader;
import com.events.CustomEvent;

var loader: CustomLoader = new CustomLoader();
loader.extraData = "Extra Data";
loader.load(new URLRequest("test.xml"));
loader.addEventListener(Event.COMPLETE, loadComplete);

function loadComplete(event: CustomEvent) : void
{
    trace(event.data); // Extra Data
}

砰！关于您天生发送的事件的自定义数据！

于 2009-04-17T02:21:36.190 回答
0

下面显示了创建自定义事件的最简洁的方法。通常事件类型具有以所有大写字母键入的公共静态引用。调度事件时，它会将一个 Event 或 CustomEvent 对象传递给事件处理程序方法。您可以在此处检索传递的值。

package com.hodgedev.events 
{
    import flash.events.Event;

    public class CustomEvent extends Event 
    {
        public static const VALUE_CHANGED:String = "VALUE_CHANGED";
        public var value:Number;

        public function CustomEvent(pValue:Number) 
        { 
            super(CustomEvent.VALUE_CHANGED);
            value = pValue;
        } 
        public override function clone():Event 
        { 
            return new CustomEvent(value);
        }
    }
}

当我们派发事件时，我们会创建一个新的事件实例来传递。

private var _someValue:int = 12;
dispatchEvent(new CustomEvent(_somevalue));
于 2009-04-17T05:44:07.403 回答