13

我将 lua 构建为外部项目，我想使用自己的 CMakeLists.txt 而不是捆绑的 Makefile。这就是我的主要 CMakeLists.txt 中的内容：

include(ExternalProject)
set(lua_RELEASE 5.1.4)
ExternalProject_Add(
    lua-${lua_RELEASE}
    URL http://www.lua.org/ftp/lua-${lua_RELEASE}.tar.gz
    DOWNLOAD_DIR ${CMAKE_CURRENT_BINARY_DIR}/download/lua-${lua_RELEASE}
    SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/lua/lua-${lua_RELEASE}
    BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/build/lua-${lua_RELEASE}
    UPDATE_COMMAND ""
    PATCH_COMMAND ""
    INSTALL_COMMAND ""
)

要使 BUILD 步骤起作用，SOURCE_DIR 中必须有一个 CMakeLists.txt。我现在在 SOURCE_DIR 中有这个 CMakeLists.txt：

cmake_minimum_required(VERSION 2.8)

project(lua)

set(lua_library
  lapi.c lcode.c ldebug.c ldo.c ldump.c lfunc.c lgc.c llex.c
  lmem.c lobject.c lopcodes.c lparser.c lstate.c lstring.c
  ltable.c ltm.c lundump.c lvm.c lzio.c
  lauxlib.c lbaselib.c ldblib.c liolib.c lmathlib.c loslib.c
  ltablib.c lstrlib.c loadlib.c linit.c
)

foreach(s ${lua_library})
    set(lua_LIBRARY ${lua_LIBRARY} src/${s})
endforeach()

add_definitions(-DLUA_ANSI=1)
add_library(lua STATIC ${lua_LIBRARY})

这行得通，但我对 lua 源文件弄乱我的版本控制 CMakeLists.txt 感到不高兴。

有没有办法为不在SOURCE_DIR中的构建步骤指定自定义 CMakeLists.txt ？

4

1 回答 1

17

我自己想通了。我现在使用它作为PATCH_COMMAND：

    PATCH_COMMAND ${CMAKE_COMMAND} -E copy
      "${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/lua/CMakeLists.txt" <SOURCE_DIR>/CMakeLists.txt

这使我可以将自定义 CMakeLists.txt 放入thirdparty/lua其中，并将上游包下载到thirdparty/lua/lua-${lua_RELEASE}. 完美的！

于 2011-09-25T21:27:59.197 回答