8

在 Mathematica 8.0 中，假设我有一些常量：


a:=7
b:=9
c:=13
d:=.002
e:=2
f:=1

我想用它们来评估一些相互关联的功能



g[0,k_]:=0
g[t_,0]:=e
g[t_,k_]:=g[t-1,k]*a+h[t-1,k-1]*b

h[0,k_]:=0
h[t_,0]:=f
h[t_,k_]:=h[t-1,k]*c+g[t-1,k-1]*d

但这真的很慢，需要动态编程，否则你会得到指数级的减速：


g[0, k_] := 0
g[t_, 0] := e
g[t_, k_] := g[t, k] = g[t - 1, k]*a + h[t - 1, k - 1]*b

h[0, k_] := 0
h[t_, 0] := f
h[t_, k_] := h[t, k] = h[t - 1, k]*c + g[t - 1, k - 1]*d

现在它真的很快，但是如果我们想要更改常量（例如，在 Manipulate 函数中使用它），我们每次都必须这样Clear g做h。如果我们有复杂的相互依赖关系，那么每次我们想要一个来自gand的值时都将它们全部清除可能真的很烦人h。

有没有一种简单的方法来运行g和h运行Module或Block类似，这样我每次评估它时都能得到一个新的结果，而不会出现指数减速？或者甚至是一种快速的方式来建立一个结果表，g并且h以一种很好的方式？如前所述，我希望能够在函数中计算g和。hManipulate

4

2 回答 2

11

这是一种方法，Block按照您的要求使用：

ClearAll[defWrap];
SetAttributes[defWrap, HoldFirst];
defWrap[fcall_] :=
  Block[{g, h},
     (* Same defintions with memoization as you had, but within Block*)

     g[0, k_] := 0;
     g[t_, 0] := e;
     g[t_, k_] := g[t, k] = g[t - 1, k]*a + h[t - 1, k - 1]*b;   
     h[0, k_] := 0;
     h[t_, 0] := f;
     h[t_, k_] := h[t, k] = h[t - 1, k]*c + g[t - 1, k - 1]*d;

     (* Our function call, but within a dynamic scope of Block *)
     fcall];

我们将使用它来定义f和h作为

ClearAll[g, h];
g[tt_, kk_] := defWrap[g[tt, kk]];
h[tt_, kk_] := defWrap[h[tt, kk]];

我们现在打电话：

In[1246]:= g[20,10]//Timing
Out[1246]= {0.,253809.}

In[1247]:= h[20,10]//Timing
Out[1247]= {6.50868*10^-15,126904.}

每次调用后都不会留下全局记忆定义——Block注意在执行退出之前销毁它们Block。特别是，这里我将更改参数并再次调用它们：

In[1271]:= 
a:=1
b:=2
c:=3
d:=.01
e:=4
f:=5

In[1279]:= g[20,10]//Timing
Out[1279]= {0.015,0.808192}

In[1280]:= h[20,10]//Timing
Out[1280]= {0.,1.01024}

该方案的替代方案是显式传递所有参数，例如a,b,c,d,e,f函数，扩展它们的形式参数列表（签名），但这有一个缺点，即对应于不同过去参数值的旧记忆定义不会被自动清除。这种方法的另一个问题是生成的代码会更脆弱，参数数量会发生变化等。

编辑

但是，如果您想构建一个结果表，这可能会更快一些，因为您一劳永逸地进行，并且在这种情况下，您确实希望保留所有已记忆的定义。所以，这里是代码：

ClearAll[g, h];
g[0, k_, _] := 0;
g[t_, 0, {a_, b_, c_, d_, e_, f_}] := e;
g[t_, k_, {a_, b_, c_, d_, e_, f_}] := 
     g[t, k, {a, b, c, d, e, f}] = 
        g[t - 1, k, {a, b, c, d, e, f}]*a +  h[t - 1, k - 1, {a, b, c, d, e, f}]*b;

h[0, k_, _] := 0;
h[t_, 0, {a_, b_, c_, d_, e_, f_}] := f;
h[t_, k_, {a_, b_, c_, d_, e_, f_}] := 
     h[t, k, {a, b, c, d, e, f}] = 
        h[t - 1, k, {a, b, c, d, e, f}]*c +  g[t - 1, k - 1, {a, b, c, d, e, f}]*d;

您调用它，显式传递参数：

In[1317]:= g[20,10,{a,b,c,d,e,f}]//Timing
Out[1317]= {0.,253809.}

（我使用的是原始参数）。在此方法中，您可以检查记忆的定义是否保留在全局规则库中。下次您调用具有完全相同参数的函数时，它将获取记忆定义而不是重新计算。除了我上面概述的这种方法的问题之外，您还应该注意内存使用情况，因为没有任何东西被清除。

于 2011-09-08T08:33:04.220 回答
8

使用辅助符号记忆

可以修改问题中展示的记忆技术，以便在需要清除缓存时不需要重新建立g和的定义。h这个想法是将记忆值存储在辅助符号上，而不是直接存储在gand上h：

g[0,k_] = 0;
g[t_,0] = e;
g[t_,k_] := memo[g, t, k] /. _memo :> (memo[g, t, k] = g[t-1,k]*a+h[t-1,k-1]*b)

h[0,k_] = 0;
h[t_,0] = f;
h[t_,k_] := memo[h, t, k] /. _memo :> (memo[h, t, k] = h[t-1,k]*c+g[t-1,k-1]*d)

除了引入了一个新符号 , 之外，这些定义与g和的原始记忆版本基本相同。有了这些定义，就可以简单地清除缓存——无需重新定义和重新定义。更好的是，缓存可以通过放置in来本地化，因此：hmemoClear@memoghmemoBlock

Block[{memo, a = 7, b = 9, c = 13, d = 0.002, e = 2, f = 1}
, Table[g[t, k], {t, 0, 100}, {k, 0, 100}]
]

当块退出时缓存被丢弃。

使用建议进行记忆

原始和修改后的记忆技术需要在功能g和h. 有时，事后引入 memoization 很方便。做到这一点的一种方法是使用建议技术——一种类似于 OO 编程中的子类化的函数式编程。函数建议的特定实现定期出现在 StackOverflow 的页面中。然而，该技术也是侵入性的。让我们考虑一种在不改变全局定义的情况下添加建议g的替代技术。h

诀窍是临时重新定义g和h在Block. 重新定义将首先检查缓存中的结果，如果失败，则从块外部调用原始定义。让我们回到最初的定义g和h幸福地不知道记忆：

g[0,k_]:=0
g[t_,0]:=e
g[t_,k_]:=g[t-1,k]*a+h[t-1,k-1]*b

h[0,k_]:=0
h[t_,0]:=f
h[t_,k_]:=h[t-1,k]*c+g[t-1,k-1]*d

该技术的基本架构如下所示：

Module[{gg, hh}
, copyDownValues[g, gg]
; copyDownValues[h, hh]
; Block[{g, h}
  , m:g[a___] := m = gg[a]
  ; m:h[a___] := m = hh[a]
  ; (* ... do something with g and h ... *)
  ]
]

引入临时符号gg和hh以保存 和 的原始g定义h。然后在本地重新绑定到新的缓存定义g，h这些定义在必要时委托给原始定义。这是 的定义copyDownValues：

ClearAll@copyDownValues
copyDownValues[from_Symbol, to_Symbol] :=
  DownValues[to] =
    Replace[
      DownValues[from]
    , (Verbatim[HoldPattern][from[a___]] :> d_) :> (HoldPattern[to[a]] :> d)
    , {1}
    ]

为了保持这篇文章的简短（呃），这个“复制”功能只关注向下值。一般建议工具还需要考虑上值、子值、符号属性等。

这种通用模式很容易实现自动化，即使很乏味。以下宏函数memoize执行此操作，几乎没有评论：

ClearAll@memoize
SetAttributes[memoize, HoldRest]
memoize[symbols:{_Symbol..}, body_] :=
  Module[{pairs, copy, define, cdv, sd, s, m, a}
  , pairs = Rule[#, Unique[#, Temporary]]& /@ symbols
  ; copy = pairs /. (f_ -> t_) :> cdv[f, t]
  ; define = pairs /. (f_ -> t_) :> (m: f[a___]) ~sd~ (m ~s~ t[a])
  ; With[{ temps = pairs[[All, 2]]
         , setup1 = Sequence @@ copy
         , setup2 = Sequence @@ define }
    , Hold[Module[temps, setup1; Block[symbols, setup2; body]]] /.
        { cdv -> copyDownValues, s -> Set, sd -> SetDelayed }
    ] // ReleaseHold
  ]

g经过一番折腾，我们现在可以在外部对and的非缓存版本进行记忆化h：

memoize[{g, h}
, Block[{a = 7, b = 9, c = 13, d = .002, e = 2, f = 1}
  , Table[g[t, k], {t, 0, 100}, {k, 0, 100}]
  ]
]

把它们放在一起，我们现在可以创建一个响应Manipulate块：

Manipulate[
  memoize[{g, h}
  , Table[g[t, k], {t, 0, tMax}, {k, 0, kMax}] //
      ListPlot3D[#, InterpolationOrder -> 0, PlotRange -> All, Mesh -> None] &
  ]
, {{tMax, 10}, 5, 25}
, {{kMax, 10}, 5, 25}
, {{a, 7}, 0, 20}
, {{b, 9}, 0, 20}
, {{c, 13}, 0, 20}
, {{d, 0.002}, 0, 20}
, {{e, 2}, 0, 20}
, {{f, 1}, 0, 20}
, LocalizeVariables -> False
, TrackedSymbols -> All
]

操纵屏幕截图

LocalizeVariables和TrackedSymbols选项是通过. _ g_haf

于 2011-09-11T17:00:49.067 回答