6

我可以使用and关键字来设置相互递归的函数定义。我也可以and用于相互递归的类型，但是如果类型和函数之间存在相互递归的关系怎么办？我唯一的选择是让函数成为类型的成员还是我也可以使用类似于and这里的东西？

编辑：添加一个简化的伪示例，我希望能说明我正在尝试做的事情

// A machine instruction type
type Instruction = Add | CallMethod int (* method ID *) | ...

// A class representing a method definition
type MethodDef (fileName : string) =
    member x.Params with get () = ...
    member x.Body with get() =
        let insts = readInstructions fileName
        Array.map toAbstractInst insts

// a more abstract view of the instructions
and AbstractInstruction = AbstAdd | AbstCallMethod MethodDef | ...

// a function that can transform an instruction into its abstract form
let toAbstractInst = function
    | Add -> AbstAdd
    | CallMethod methodId -> AbstCallMethod (somehowResolveId methodId)
    | ...

所以你可以在这里看到递归关系是相当间接地建立起来的： MethodDef <-> AbstractInst AND MethodDef -> toAbstractInst -> AbstractInstruction （其中 -> 表示“依赖于”）

4

1 回答 1

10

这个问题没有例子很难回答

  • 如果您有没有成员的相互递归类型，则类型不需要了解函数（因此您可以先定义类型，然后定义函数）。

  • 如果您有相互递归的类型，这些类型具有作为成员的功能，那么成员可以看到彼此（跨类型），您应该没问题

唯一棘手的情况是当您具有相互递归的类型、相互递归的函数并且您还希望将某些函数公开为成员时。然后你可以使用类型扩展：

// Declare mutually recursive types 'A' and 'B'
type A(parent:option<B>) =
  member x.Parent = parent

and B(parent:option<A>) =
  member x.Parent = parent

// Declare mutually recursive functions 'countA' and 'countB'
let rec countA (a:A) =
  match a.Parent with None -> 0 | Some b -> (countB b) + 1
and countB (b:B) =
  match b.Parent with None -> 0 | Some a -> (countA a) + 1

// Add the two functions as members of the types
type A with 
  member x.Count = countA x

type B with 
  member x.Count = countB x

在这种情况下，您可以只创建countA和countB这两种类型的成员，因为这样会更容易，但是如果您想将更复杂的代码编写为函数，那么这是一个选择。

如果所有内容都编写在单个模块中（在单个文件中），则 F# 编译器将类型扩展编译为标准实例成员（因此从 C# 的角度来看，它看起来就像普通类型）。如果您在单独的模块中声明扩展，则它们将被编译为特定于 F# 的扩展方法。

于 2011-08-13T16:21:24.100 回答