0

这是我当前的代码，但它很丑陋，我担心非常大或小的数字可能会出现边缘情况。有一个更好的方法吗？

real_to_int(n)={
    if(n==floor(n),return(floor(n)));   \\ If "n" is a whole number we're done
    my(v=Vec(strprintf("%g",n)));       \\ Convert "n" to a zero-padded character vector
    my(d=sum(i=1,#v,i*(v[i]==".")));    \\ Find the decimal point
    my(t=eval(concat(v[^d])));          \\ Delete the decimal point and reconvert to a number
    my(z=valuation(t,10));              \\ Count trailing zeroes
    t/=10^z;                            \\ Get rid of trailing zeroes
    return(t)
}
4

2 回答 2

3

您可以将输入实数拆分为整数和小数部分，而无需查找点。

real_to_int(n) = {
    my(intpart=digits(floor(n)));
    my(fracpartrev=fromdigits(eval(Vecrev(Str(n))[1..-(2+#intpart)])));
    fromdigits(concat(intpart, Vecrev(digits(fracpartrev))))
};

real_to_int(123456789.123456789009876543210000)
> 12345678912345678900987654321

请注意，数字列表中所有前导零的组成digits和消除。fromdigits

于 2021-10-27T22:22:45.630 回答
2

这个问题没有很好的定义，因为从实数（内部存储为二进制）到十进制字符串的转换可能需要四舍五入，并且如何完成取决于许多因素，例如format默认值或当前bitprecision.

有可能获得t_REALas m * 2^e 的内部二进制表示，其中m和e都是整数。

install(mantissa2nr, GL);
real_to_int(n) =
{
   e = exponent(n) + 1 - bitprecision(n);
   [mantissa2nr(n, 0), e];
}

? [m, e] = real_to_int(Pi)
%1 = [267257146016241686964920093290467695825, -126]

? m * 1. * 2^e
%2 = 3.1415926535897932384626433832795028842

使用 [m, e] 我们获得了数字的精确（有理）内部表示，并且两者都定义良好，即独立于所有设置。m是十进制请求的二进制等效项。

于 2021-11-04T02:03:36.793 回答