0

我已经设法在我的 Flex 程序中有效地匹配有效的字符串文字，但我也想匹配未终止的字符串文字和带有错误转义序列的字符串文字。

例如，我的字符串文字使用简单的正则表达式进行匹配，如下所示：

\"(\\.|[^\\"])*\"

然后我试图找到一个字符串文字的开始位置，"然后是一些文本，然后是\n. 这对我的词法分析器来说是不正确的语法，我想捕捉并产生一个错误。

我想出的当前正则表达式是这样的：

\"(\\.|[^\\"])*\n

哪个确实正确捕获了错误，但随后似乎吃掉了其余的令牌，因为在那之后没有输出。

此外，我还希望在未终止的字符串文字具有无效的转义序列时出现特殊情况错误。例如：

"some text \
int abc

所以我的问题归结为，我当前匹配字符串文字的方式是否有问题影响了我捕捉这些错误的能力，或者我的模式匹配是否不必要地消耗了令牌？也有可能我不知道我在做什么！

字符串的一些示例：

"a correct string literal"
"an unterminated string literal
"an unterminated string literal with escape \

所有字符串文字都是单行的并遵循以下形式：

"(.*)"\n
4

1 回答 1

1

字符串文字的正确弹性模式是（转义序列见下文）：

\"(\\(.|\n)|[^\\"\n])*\"

这与您的模式不同，因为它允许在转义字符后换行（从技术上讲，这是一个拼接，而不是字符串文字 [注 1] 语法的一部分），否则禁止换行。这必须明确完成，因为[^...]包括换行符，除非\n是要拒绝的字符列表的一部分。仅.隐式禁止换行符。

要匹配不正确的字符串文字，您只需要没有终止符的相同模式"：

\"(\\(.|\n)|[^\\"\n])*

您不必担心模式匹配正确的字符串文字，因为 flex 总是选择最长的匹配，并且与终止引号的匹配保证更长。

如果您想更准确地了解转义字符，则需要以下内容：

\"(\\([abfnrtv'"?\\\n]|[0-7]{1,3}|x[[:xdigit:]]+|u[[:xdigit:]]{4}|U[[:xdigit:]]{8})|[^\\"\n])*\"

您可以使用相同的技术来匹配错误，但您可能想要区分未终止的引号错误和无效的转义错误，您可以使用两种错误模式来做到这一点：

\"(\\([abfnrtv'"?\\\n]|[0-7]{1,3}|x[[:xdigit:]]+|u[[:xdigit:]]{4}|U[[:xdigit:]]{8})|[^\\"\n])*\"   { /* Valid string */ }
\"(\\([abfnrtv'"?\\\n]|[0-7]{1,3}|x[[:xdigit:]]+|u[[:xdigit:]]{4}|U[[:xdigit:]]{8})|[^\\"\n])*/\\  { /* Invalid escape sequence */ }
\"(\\([abfnrtv'"?\\\n]|[0-7]{1,3}|x[[:xdigit:]]+|u[[:xdigit:]]{4}|U[[:xdigit:]]{8})|[^\\"\n])*     { /* Missing terminating quote */ }

笔记

  1. “拼接”是行尾的反斜杠。您通常只在长宏的定义中看到这些，但 C 允许在任何地方进行拼接：反斜杠和以下换行符只是从程序文本中删除，因此拼接甚至可以放在标识符或多字符运算符的中间。（但不要那样做！）

    使用拼接在多行上继续字符串不是好的风格；最好使用字符串连接。但是 C 标准确实允许这样做。

    但是，在标记化开始之前会删除拼接，这意味着您不能在行尾使用反斜杠转义反斜杠：

    "This is a string literal which includes a \\
t tab, with a splice in the middle of the escape."

    请不要在生产代码中使用它:-)

于 2021-09-02T01:11:53.807 回答