0

假设我有一个像这样的 XML：

<A>
<B n='key1' v='value1'/>
<B n='key2' v='value2'/>
<B n='key3' v='value3'/>
<B n='key4' v='value4'/>
</A>

注意：这只是我提供的 4 行，但它有这么多行（B 标签）。

我想把它变成：

<XYZ name='value1'>
<MNP>value2</MNP>
</XYZ>
<XYZ name='value3'>
<MNP>value4</MNP>
</XYZ>

我需要在 azure apim 中做。

4

1 回答 1

0

使用 XSLT 2 或 3 中的位置分组，您可以使用

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  expand-text="yes">

  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="A">
    <xsl:copy>
      <xsl:for-each-group select="B" group-adjacent="(position() - 1) idiv 2">
        <XYZ name="{@v}">
          <MPN>{current-group()[2]/@v}</MPN>
        </XYZ>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

使用 XSLT 1，您可以处理B[position() mod 2 = 1]创建XYZ元素，然后导航following-sibling::B[1]到创建MPN元素：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="xml" indent="yes"/>
  
  <xsl:template match="A">
    <xsl:copy>
      <xsl:for-each select="B[position() mod 2 = 1]">
        <XYZ name="{@v}">
          <MPN>
            <xsl:value-of select="following-sibling::B[1]/@v"/>
          </MPN>
        </XYZ>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>
于 2021-07-13T14:48:42.090 回答