0

我有一个数据要注入到这个多级哈希中：

$newcomm_stat_hash{$stat_message_class}{$stat_process} = $stat_host;

我可以用键值结构打印出$stat_message_class, 和：$stat_process

foreach my $stat_message_class (keys %newcomm_stat_hash) {

   my $stat_message_type = $stat_message_class;

   foreach my $stat_process (keys %{$newcomm_stat_hash{$stat_message_class}} ) {

      print $stat_host;
   }
}

但是当我按照相同的格式打印出来$stat_host values（见下面的代码）时，我收到了这个错误消息：

在 multilevel_hash 第 24 行使用“strict refs”时，不能使用字符串（“dc109”）作为 HASH 引用。

对于键或值功能，我得到了相同的消息。

#!/usr/bin/perl
use warnings; 
use strict;

my %newcomm_stat_hash; 
my $control_server = "dc100";
my $control_stat_message = "OCCD2o";

$newcomm_stat_hash{'OCCD2o'} =  { 'filesrvr' => 'dc100',
                                  'dhcpsrv'  => 'dc100',
                                  'dnssrv'   => 'dc109',
                                  'mailpfd'  => 'dc100',
                                };

$newcomm_stat_hash{'PIDmon2'} = { 'pingstat' => 'fg100',
                                  'udpmon'   => 'fg100',
                                  'ftp'      => 'dc100',
                                  'casper'   => 'dc440',
                                };

foreach my $stat_message_class ( keys %newcomm_stat_hash ) {

 my $stat_message_type = $stat_message_class;

 foreach my $stat_process ( keys %{$newcomm_stat_hash{$stat_message_class}} ) {

         foreach my $stat_host (keys %{$newcomm_stat_hash{$stat_message_class}{$stat_process}} ) {

             print $stat_host;
         } 
     }
}

在取消对多级哈希的引用后，$stat_host我想在最后插入它：

use TERM::ANSIColor;

if ($stat_host ne $control_server) {

    print "$stat_host, $stat_process , $stat_message_class";   
}   

elsif (  ($stat_host ne $control_server)
      && ($stat_message_class eq $control_stat_message)
      ) {   

    print color 'red';   
    print "$stat_host, $stat_process , $stat_message_class";
    print color 'reset';   
}
4

2 回答 2

1

如果我正确理解您的代码，您的说法OCCD2o是“消息类”，filesrvr是“进程”并且dc100是“主机”。如果是这种情况，则不需要最里面的“foreach”循环，因为您已经处于哈希引用的“主机”级别。你不能在那个层次上更深入。

因此，如果将表达式重写%{$newcomm_stat_hash{$stat_message_class} {$stat_process}}为：

$tmp = $newcomm_stat_hash{$stat_message_class}{$stat_process}
$hash = %{$tmp}

然后$tmp被评估为一个字符串标量dc109，该标量不能作为散列取消引用，因此显示错误消息。

我会说这是正确的循环结构：

foreach my $stat_message_class(keys %newcomm_stat_hash){
    my $stat_hash = $newcomm_stat_hash{$stat_message_class};
    my $stat_message_type = $stat_message_class;
    foreach my $stat_process (keys %{$stat_hash}){
        my $stat_host = $stat_hash->{$stat_process};

        print $stat_message_class, " / ", $stat_process, " / ", $stat_host, "\n";
    }
}
于 2011-07-23T05:24:02.350 回答
0

看起来这里的目标是在$control_server与$control_stat_message红色相对应的哈希条目中打印。

如果是这样，条件将不会按照您的意愿执行，因为该elsif子句永远不会执行。

#!/usr/bin/perl
use warnings; 
use strict;
use Term::ANSIColor;

my %newcomm_stat_hash; 
my $control_server       = "dc100";
my $control_stat_message = "OCCD2o";

$newcomm_stat_hash{'OCCD2o'} =  { 'filesrvr' => 'dc100',
                                  'dhcpsrv'  => 'dc100',
                                  'dnssrv'   => 'dc109',
                                  'mailpfd'  => 'dc100',
                                };

$newcomm_stat_hash{'PIDmon2'} = { 'pingstat' => 'fg100',
                                  'udpmon'   => 'fg100',
                                  'ftp'      => 'dc100',
                                  'casper'   => 'dc440',
                                };

foreach my $stat_message_class ( keys %newcomm_stat_hash ) {

    my $message_class = $newcomm_stat_hash{$stat_message_class};

    foreach my $stat_process ( keys %{ $message_class } ) {

        my $host = $message_class->{$stat_process};

        my $info = join(', ', $stat_message_class, $stat_process, $host) . "\n";

        if (   $stat_message_class eq $control_stat_message
           &&  $host eq $control_server
           )
        {

            print colored ( $info, 'red' );  # Prints $info in red
        }

        else {

            print $info;                     # Prints $info normally
        }
    }
}
于 2011-07-23T07:48:35.683 回答