5

对于常规的 gradle 操作，我的gradle.properties项目或主页中有一个文件，用于配置代理详细信息（主机/端口等）

使用时GradleRunner，有意忽略该gradle.properties文件：
“默认 Gradle 用户主目录（例如 ~/.gradle/gradle.properties）中的任何配置均不用于测试执行。TestKit 未公开用于细粒度控制的机制环境的所有方面（例如，JDK）。TestKit 的未来版本将提供改进的配置选项。

（来自https://docs.gradle.org/current/userguide/test_kit.html#sec:controlling_the_build_environment）

问题：
使用时如何配置代理GradleRunner？

4

1 回答 1

1

您可以简单地将gradle.properties带有代理设置的文件添加到您的测试项目（使用 运行GradleRunner）。这是一个完整的示例项目（Gradle 7.1 Wrapper 文件未显示）：

├── build.gradle
└── src
    └── test
        └── groovy
            └── com
                └── example
                    └── MyTest.groovy

build.gradle

plugins {
    id 'groovy'
    id 'java-gradle-plugin'
}

repositories {
  mavenCentral()
}

dependencies {
    testImplementation('org.spockframework:spock-core:2.0-groovy-3.0')
}

test {
    useJUnitPlatform()
}

src/test/groovy/com/example/MyTest.groovy

package com.example

import org.gradle.testkit.runner.GradleRunner
import static org.gradle.testkit.runner.TaskOutcome.*
import spock.lang.TempDir
import spock.lang.Timeout
import spock.lang.Specification

class MyTest extends Specification {

    @TempDir File projDir

    @Timeout(10)
    def "network connection through proxy works"() {
        given:
        def myTestTask = 'foo'
        new File(projDir, 'settings.gradle') << "rootProject.name = 'my-test'"
        new File(projDir, 'gradle.properties') << '''\
            systemProp.http.proxyHost = 192.168.123.123
            '''
        new File(projDir, 'build.gradle') << """\
            task $myTestTask {
                doLast {
                    println(new java.net.URL('http://www.example.com').text)
                }
            }
            """

        when:
        def result = GradleRunner.create()
            .withProjectDir(projDir)
            .withArguments(myTestTask)
            .build()

        then:
        result.task(":$myTestTask").outcome == SUCCESS
    }
}

我使用了一个不存在的虚拟代理，由于测试/连接超时 (→ SpockTimeoutError) 而导致测试失败。使用真正的代理，测试应该会成功。

于 2021-06-15T09:10:46.520 回答