1

我有一个 common.tfvars 文件，其中变量定义为：

bqtable_date_partition = [
  { dataset = "d1", table_name = "d1-t1", part_col = "partition_date",
  part_type = "DAY", schema_file = "data_tables/d1-t1.json" },

  { dataset = "d1", table_name = "d1-t2", part_col = "tran_dt",
  part_type = "DAY", schema_file = "data_tables/d1-t2.json" },

  { dataset = "d2", table_name = "d2-t1", part_col = "tran_dt",
  part_type = "DAY", schema_file = "data_tables/d2-t1.json" },
]

我在 main.tf 文件中使用以下资源定义引用此 var：

resource "google_bigquery_table" "bq_tables_dt_pt" {
  count      = length(var.bqtable_date_partition)
  project    = var.project_id
  dataset_id = "${var.bqtable_date_partition[count.index].dataset}_${var.env}"
  table_id   = var.bqtable_date_partition[count.index].table_name
  time_partitioning {
    type  = var.bqtable_date_partition[count.index].part_type
    field = var.bqtable_date_partition[count.index].part_col
  }
  schema     = file("${path.module}/tables/${var.bqtable_date_partition[count.index].schema_file}")
  depends_on = [google_bigquery_dataset.crte_bq_dataset]
  labels = {
    env        = var.env
    ind        = "corp"
  }
}

我想更改资源定义以使用“for_each”而不是“count”来循环列表：

我从 count 更改为 for_each 的动机是消除对我编写变量“bqtable_date_partition”元素的顺序的依赖

我这样做了：

resource "google_bigquery_table" "bq_tables_dt_pt" {
  for_each   = var.bqtable_date_partition
  project    = var.project_id
  dataset_id = "${each.value.dataset}_${var.env}"
  table_id   = each.value.table_name
  time_partitioning {
    type  = each.value.part_type
    field = each.value.part_col
  }
  schema     = file("${path.module}/tables/${each.value.schema_file}")
  depends_on = [google_bigquery_dataset.crte_bq_dataset]
  labels = {
    env        = var.env
    ind        = "corp"
  }
}

我按预期收到以下错误：

给定的“for_each”参数值不合适：“for_each”参数必须是一个映射或一组字符串，并且您提供了一个字符串映射列表类型的值。

谁能帮助我在资源定义中进行哪些更改才能使用“for_each”？

Terraform 版本 - 0.14.x

4

2 回答 2

1

错误说它只接受地图或字符串集。所以我们必须将输入变量转换为映射或字符串集。

https://www.terraform.io/docs/language/expressions/for.html

resource "google_bigquery_table" "bq_tables_dt_pt" {
  for_each   = { for index, data_partition in var.bqtable_date_partition : index => data_partition }
  project    = var.project_id
  dataset_id = "${each.value.dataset}_${var.env}"
  table_id   = each.value.table_name
  time_partitioning {
    type  = each.value.part_type
    field = each.value.part_col
  }
  schema     = file("${path.module}/tables/${each.value.schema_file}")
  depends_on = [google_bigquery_dataset.crte_bq_dataset]
  labels = {
    env = var.env
    ind = "corp"
  }
}

所以基本上，我们在这里将 for_each 输入转换为以下格式。并且仅从新创建的地图中引用值。

{
  "0" = {
    "dataset" = "d1"
    "part_col" = "partition_date"
    "part_type" = "DAY"
    "schema_file" = "data_tables/d1-t1.json"
    "table_name" = "d1-t1"
  }
  "1" = {
    "dataset" = "d1"
    "part_col" = "tran_dt"
    "part_type" = "DAY"
    "schema_file" = "data_tables/d1-t2.json"
    "table_name" = "d1-t2"
  }
  "2" = {
    "dataset" = "d2"
    "part_col" = "tran_dt"
    "part_type" = "DAY"
    "schema_file" = "data_tables/d2-t1.json"
    "table_name" = "d2-t1"
  }
}
于 2021-06-02T17:45:20.087 回答
1

使用有两个主要要求for_each：

  • 对于要声明的每个资源实例，您必须拥有一个包含一个元素的集合。
  • 必须有某种方法从该集合的每个元素中派生唯一标识符，然后 Terraform 将使用该标识符作为唯一实例键。

看起来您的集合符合这两个标准，假设它table_name是所有这些值的唯一字符串，所以剩下的就是将集合投影到地图中，以便 Terraform 可以从您打算使用的键中看到table_name对于唯一的跟踪键：

resource "google_bigquery_table" "bq_tables_dt_pt" {
  for_each = {
    for o in var.bqtable_date_partition : o.table_name => o
  }

  # ...
}

在这里，我使用for表达式从序列投影到映射，其中每个元素都由其table_name属性中的值标识。

如果您处于能够更改此模块的接口的情况，那么您可以通过更改变量的声明以期望映射而不是列表来简化事情，这样就可以避免需要投影并使其显式向模块调用者表明表 ID 必须是唯一的：

variable "bqtable_date_partition" {
  type = map(object({
    dataset     = string
    part_col    = string
    part_type   = string
    schema_file = string
  }))
}

然后你可以像之前尝试的那样var.bqtable_date_partition直接分配给for_each，因为它已经是合适的类型。但也需要更改调用模块以传递映射值而不是列表值，因此如果您的模块有许多调用者都需要更新以保持兼容，这可能不切实际。

于 2021-06-03T00:56:50.827 回答