0

我对如何在加法合成中实现参数感到很困惑。

我正在尝试实现一个系统，我可以在其中对以下参数进行排序：任意数量的部分，基本频率。我不确定任意数量的部分的可行性，但在我看来，对基频进行排序确实应该是完全可能的。

这是我正在处理的代码：

(
    z = {
        arg index, freq, nn;
        var finalFreq, ff, amp, nn;
        ff = index*freq;
        amp = 0.5/nn;
        finalFreq = freq + ff;
        finalFreq.postln;
        s = SinOsc.ar(finalFreq, 0, amp);
    };
)

(
SynthDef.new('additive',{
    arg freq, nn;
    var sig, env;
    env = Line.kr(1,0,0.2);
    sig = Mix.fill(nn, z) * env;
    Out.ar(0,sig);
}).add
)

(p = Pbind(
    \instrument, \additive,
    \dur, Pseq([0.1,0.2,0.3,0.4],inf),
    \freq, Pseq([100,440,880,55],inf),
    \nn, Pseq([1,5,10,100],inf)
).play;
)

这失败了Index not an Integer。而且我什至不确定如何向 z 发送参数。

我设想利用变量范围的另一种表述如下：

(
SynthDef.new('additive',{
    arg freq, nn;
    var sig, env;
    env = Line.kr(1,0,0.2);
    z = {
        arg index;
        var finalFreq, ff, amp, nn;
        ff = index*freq;
        amp = 0.5/nn;
        finalFreq = freq + ff;
        finalFreq.postln;
        s = SinOsc.ar(finalFreq, 0, amp);
    };

    sig = Mix.fill(nn, z) * env;
    Out.ar(0,sig);
}).add
)

它也不起作用，失败了Index not an Integer。

你将如何解决这个问题？

4

1 回答 1

2

Mix.fill 会在创建 Synth 时创建一个数组，因此您不能使用 Synth 参数动态更改数组的大小。

您的底部示例还在函数nn内声明为变量z，这意味着amp = 0.5/nil

一种可能的解决方案是制作多个 SynthDef。假设您知道您想要的 SinOscs 的最小数量是 2，最大数量是 25。

(
(2..25).do({ arg nn;
    
    SynthDef.new('additive'++nn,{
        arg freq;
        var sig, env;
        env = Line.kr(1,0,0.2);
        z = {
            arg index;
            var finalFreq, ff, amp;
            ff = index*freq;
            amp = 0.5/nn;
            finalFreq = freq + ff;
            finalFreq.postln;
            s = SinOsc.ar(finalFreq, 0, amp);
        };
        
        sig = Mix.fill(nn, z) * env;
        Out.ar(0,sig);
    }).add
});
)

这将为您提供名为additive2、additive3、additive4、...additive25 的SynthDef。

当你想改变数组的大小时，你必须改变你正在播放的 SynthDef。这是一个 Pbind，它从您的加法 SynthDef 之间随机选择：

Pbind(
    \instrument, Pfunc({ 'additive' ++ 2.rrand(25) })
).play

或者，要使用顶级示例中的 pbind ：

(
n = [1,5,10,100];

n.do({ arg nn;
    
    SynthDef.new('additive'++nn,{
        arg freq;
        var sig, env;
        env = Line.kr(1,0,0.2);
        z = {
            arg index;
            var finalFreq, ff, amp;
            ff = index*freq;
            amp = 0.5/nn;
            finalFreq = freq + ff;
            finalFreq.postln;
            s = SinOsc.ar(finalFreq, 0, amp);
        };
        
        sig = Mix.fill(nn, z) * env;
        Out.ar(0,sig);
    }).add
});
)

Pbind(
    \instrument, Pfunc({ 'additive' ++ n.choose }),
    \dur, Pseq([0.1,0.2,0.3,0.4],inf),
    \freq, Pseq([100,440,880,55],inf)
).play
于 2021-05-25T13:32:42.467 回答