5

在 Intellij Idea 中，有一个特性。假设我myCamelCase在代码的某处使用了一个变量。然后，如果我键入mCC并按Ctrl-Enter或一些这样的组合键，它会扩展为myCamelCase. Vim中有类似的东西吗？

4

2 回答 2

8

好的，请原谅我回答了两次，但由于我的第一次尝试没有抓住重点，我会再试一次。这比我想象的要复杂，但可能没有我做的那么复杂（！）。

现在修改为建议所有匹配的变量名称。

首先，这是一个从“myCamelCase”字符串生成“mCC”缩写的函数：

function! Camel_Initials(camel)
    let first_char = matchstr(a:camel,"^.")
    let other_char = substitute(a:camel,"\\U","","g")
    return first_char . other_char
endfunction

现在，这里有一个函数，它采用缩写（'mCC'）并扫描当前缓冲区（从当前行向后）以查找具有此缩写的“单词”。返回所有匹配项的列表：

function! Expand_Camel_Initials(abbrev)
    let winview=winsaveview()
    let candidate=a:abbrev
    let matches=[]
    try
        let resline = line(".")
        while resline >= 1
            let sstr = '\<' . matchstr(a:abbrev,"^.") . '[a-zA-Z]*\>'
            keepjumps let resline=search(sstr,"bW")
            let candidate=expand("<cword>")
            if candidate != a:abbrev && Camel_Initials(candidate) == a:abbrev
                call add( matches, candidate )
            endif
        endwhile
    finally
        call winrestview(winview)
        if len(matches) == 0
            echo "No expansion found"
        endif
        return sort(candidate)
    endtry
endfunction

接下来，这是一个自定义完成函数，它读取光标下的单词并建议上述函数返回的匹配项：

function! Camel_Complete( findstart, base )
    if a:findstart
        let line = getline('.')
        let start = col('.') - 1
        while start > 0 && line[start - 1] =~ '[A-Za-z_]'
            let start -= 1
        endwhile
        return start
    else
        return Expand_Camel_Initials( a:base )
    endif
endfunction

要使用它，您必须定义“completefunc”：

setlocal completefunc=Camel_Complete

要使用插入模式完成，请键入CTRL-X CTRL-U，但我通常将其映射到CTRL-L：

inoremap <c-l> <c-x><c-u>

使用 vimrc 中的此代码，您应该会发现键入mCC后跟CTRL-L将进行预期的替换。如果未找到匹配的展开式，则缩写保持不变。

该代码不是无懈可击的，但它适用于我测试的所有简单案例。希望能帮助到你。让我知道是否有任何需要说明的地方。

于 2011-07-01T16:26:45.580 回答
0

Vim 中有一个名为vim-abolish的插件。使用地图crc展开为驼峰式。

于 2016-03-31T13:50:03.840 回答