3

假设我有一些想要转换为 HTML 的 XML。XML 分为有序的部分：

<?xml version="1.0" encoding="utf-8"?>
<root>
  <section attr="someCriteria">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
  </section>
  <section attr="someOtherCriteria">
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </section>
  <section attr="anotherSetOfCriteria">
    <warning>
      Warning: This product could kill you
    </warning>
  </section>
  <section attr="evenMoreCriteria">
    <disclaimer>
      You were warned
    </disclaimer>
  </section>
  <section attr="criteriaSupreme">
    <p>Copyright 1999-2011</p>
  </section>
</root>

我有几个这样的 XML 文档。我需要根据标准对这些部分进行分组和转换。将有两种不同的桶。

  • 所以第一部分将放在一个桶中（例如<div class="FormatOne"></div>）
  • 如果第二部分符合“FormatOne”存储桶的条件，它也将进入该存储桶
  • 如果第三部分需要不同的存储桶（例如<div class="FormatTwo"></div>），则创建一个新存储桶并将部分内容放置在此存储桶中
  • 如果第四部分的存储桶需要“FormatOne”（与以前的格式不同），则再次创建一个新存储桶并将部分内容放置在此存储桶中
  • 等等。如果它们的格式相同，每个部分将与前一部分进入相同的存储桶。如果不是，则创建一个新存储桶。

因此，对于每个文档，根据分离桶的逻辑，文档可能会像这样结束：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </div>
  <div class="FormatTwo">
    <span class="warningText">
      Warning: This product could kill you
    </span>
  </div>
  <div class="FormatOne">
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

这个：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
  </div>
  <div class="FormatTwo">
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </div>
  <div class="FormatOne">
    <span class="warningText">
      Warning: This product could kill you
    </span>
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

甚至这个：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
    <span class="warningText">
      Warning: This product could kill you
    </span>
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

取决于部分的定义方式。

有没有办法使用 XSLT 来执行这种类型的分组魔术？

任何帮助都会很棒。谢谢！

4

3 回答 3

3

我想出了一个解决方案，包括按顺序点击每个部分。每个部分的处理分为两部分：“外壳”和“内容”部分。“shell”负责渲染<div class="FormatOne">...</div>位，“contents”负责渲染当前节和所有后续节的实际内容，直到找到不匹配的节。

当找到不匹配的部分时，控制恢复到该部分的“shell”模板。

这提供了一些有趣的灵活性：“shell”模板可能在它们匹配的内容上非常激进，而“内容”部分可能更挑剔。具体来说，在您的第一个示例输出中，您需要将warning元素显示为<span class="warningText">...</span>，这可以通过更匹配的模板来完成。

所有“内容”模板在呈现其当前部分的内容后，调用一个命名模板来查找“下一个”适当的内容部分。这有助于巩固用于确定什么是“匹配”部分的规则。

您可以在此处查看一个工作示例。

这是我的代码，用于复制您在第一个示例中要求的内容：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" />

    <xsl:template match="/">
        <body>
            <xsl:apply-templates select="/root/section[1]" mode="shell" />
        </body>
    </xsl:template>

    <xsl:template match="section[
        @attr = 'someCriteria' or
        @attr = 'someOtherCriteria' or
        @attr = 'evenMoreCriteria' or
        @attr = 'criteriaSupreme']" mode="shell">

        <div class="FormatOne">
            <xsl:apply-templates select="." mode="contents" />
        </div>

        <xsl:apply-templates select="following-sibling::section[
            @attr != 'someCritera' and
            @attr != 'someOtherCriteria' and
            @attr != 'evenMoreCriteria' and
            @attr != 'criteriaSupreme'][1]" mode="shell" />

    </xsl:template>

    <xsl:template name="nextFormatOne">
        <xsl:variable name="next" select="following-sibling::section[1]" />
        <xsl:if test="$next[
            @attr = 'someCriteria' or
            @attr = 'someOtherCriteria' or
            @attr = 'evenMoreCriteria' or
            @attr = 'criteriaSupreme']">
            <xsl:apply-templates select="$next" mode="contents" />
        </xsl:if>
    </xsl:template>

    <xsl:template match="section[
        @attr = 'someCriteria' or
        @attr = 'someOtherCriteria']" mode="contents">

        <xsl:copy-of select="*" />

        <xsl:call-template name="nextFormatOne" />
    </xsl:template>

    <xsl:template match="section[@attr = 'evenMoreCriteria']" mode="contents">
        <span class="disclaimerText">
            <xsl:value-of select="disclaimer" />
        </span>

        <xsl:call-template name="nextFormatOne" />
    </xsl:template>

    <xsl:template match="section[@attr = 'criteriaSupreme']" mode="contents">
        <p class="copyright">
            <xsl:value-of select="p" />
        </p>

        <xsl:call-template name="nextFormatOne" />
    </xsl:template>

    <xsl:template match="section[@attr = 'anotherSetOfCriteria']" mode="shell">
        <div class="FormatTwo">
            <xsl:apply-templates select="." mode="contents" />
        </div>
        <xsl:apply-templates select="
            following-sibling::section[@attr != 'anotherSetOfCriteria'][1]"
            mode="shell" />
    </xsl:template>

    <xsl:template name="nextFormatTwo">
        <xsl:variable name="next" select="following-sibling::section[1]" />
        <xsl:if test="$next[@attr = 'anotherSetOfCriteria']">
            <xsl:apply-templates select="$next" mode="contents" />
        </xsl:if>
    </xsl:template>

    <xsl:template
        match="section[@attr = 'anotherSetOfCriteria']"
        mode="contents">

        <span class="warningText">
            <xsl:value-of select="warning" />
        </span>

        <xsl:call-template name="nextFormatTwo" />
    </xsl:template>

</xsl:stylesheet>
于 2011-06-23T01:46:45.290 回答
1

“如果每个部分的格式相同，则每个部分都将进入与前一部分相同的存储桶。如果不是，则创建一个新存储桶。”

您所描述的本质上是指令执行的任务

<xsl:for-each-group group-adjacent="....">

在 XSLT 2.0 中。这假设您可以编写一个将您的“标准”转换为存储桶名称的函数，并在 group-adjacent 属性中调用此函数。

那么，您需要使用 XSLT 1.0 的约束有多大？

如果您坚持使用 1.0，那么您将不得不使用 Chris Nielsen 提出的兄弟递归设计模式。

于 2011-06-23T09:07:13.727 回答
0

查看template,和: if_choosefor-each

这些（以及其他 XSLT 元素）将允许您进行条件行为以在不同的转换逻辑之间切换。

于 2011-06-23T00:51:34.460 回答