for-loop - gnuplot：在 for 循环中设置线条样式

Question

我必须在同一张图上绘制几条曲线。我必须使用 for 循环来执行此操作。我想用线绘制两条第一条曲线，用点绘制其他曲线。我能够用线绘制所有曲线或用点绘制所有曲线，但不能在同一个 for 循环中改变。这是我的代码的相关部分：
set style line 1 lw 1 lc rgb "green"
set style line 2 lw 1 lc rgb "purple"
set style line 3 pt 1 ps 1.0 lc rgb "red"
set style line 4 pt 2 ps 1.0 lc rgb "red"
set style line 5 pt 3 ps 1.0 lc rgb "red"
plot for [i=1:words(FILES)] myDataFile(i) u (column(1)):((word(UTAUS_ch,i))) ls i title myTitle(i)

我想在“ ls i ”前加上“ wl ”代表前两条曲线，而“ ls i ”代表其他曲线。我尝试通过将“ ls i ”替换为“ if (i < 2) {wl ls i} else {ls i} ”来使用 if 语句，但 Gnuplot 不希望在此位置找到 if 语句。

有人能帮我吗 ？谢谢你，马丁

Answer 1

如前所述，您可能无法在plot for循环中切换绘图样式。所以，要么你做两个单独with points的循环，一个和另一个with lines，或者你做一个循环with linespoints并将点和线的所有必要参数定义为函数（以保持绘图命令可读）。正如这里提到的，linewidth 0不是零，而是最细的线，通常是 1 个像素。要使线条完全消失，您必须使用linetype -2.

代码：

### lines and points in the same plot for-loop
reset session

LINECOLORS = "red  green blue  magenta cyan"
LINEWIDTHS = '1.0  4.0   0.0   0.0     0.0'
POINTTYPES = '0    0     5     7       9'
POINTSIZES = '0    0     1.0   2.0     3.0'
TITLES     = 'one  two   three four    five'

myLinecolor(i) = word(LINECOLORS,i)
myLinewidth(i) = real(word(LINEWIDTHS,i))
myPointtype(i) = int(word(POINTTYPES,i))
myPointsize(i) = real(word(POINTSIZES,i))
myLinetype(i) = myLinewidth(i) == 0 ? -2 : 1
myTitle(i) = word(TITLES,i)

set samples 31
set key out

plot for [i=1:words(TITLES)] (sin(0.25*x-i)) w lp pt myPointtype(i) ps myPointsize(i) \
    lt myLinetype(i) lw myLinewidth(i) lc rgb myLinecolor(i) title myTitle(i)
### end of code

结果：

添加：

为了使绘图命令尽可能简短和清晰，您还可以定义线条样式并在plot for命令中使用它 via ls i，结果与上面相同。

...

do for [i=1:words(TITLES)] {
    set style line i pt myPointtype(i) ps myPointsize(i) \
        lt myLinetype(i) lw myLinewidth(i) lc rgb myLinecolor(i)
}

plot for [i=1:words(TITLES)] (sin(0.25*x-i)) w lp ls i title myTitle(i)

Answer 2

这是使用宏的一种方式：

set style line 1 lw 1 lc rgb "green"
set style line 2 lw 1 lc rgb "purple"
set style line 3 pt 1 ps 1.0 lc rgb "red"
set style line 4 pt 2 ps 1.0 lc rgb "red"
set style line 5 pt 3 ps 1.0 lc rgb "red"

set samp 100
set macro
cmd = ''
do for [i=1:10] {s = i<3? 'w l' : 'ls '.i; 
                 cmd = cmd . '"+" us  1:(sin(x-'.i.'/10.)) '.s.' title "key '.i.'",'}

plot [0:2*pi] @cmd