2

AddressOf我的愿望是通过一个输入参数按名称运行给定的函数，例如Function Foo(x as Integer) As Integer. 我在递归函数中需要的两个输入是函数名_name As String和某种类型的对象 t _list As t（整数、双精度、列表（整数）等）。目标是处理具有函数名称的元素或元素列表，因为有多次我需要通过给定函数处理列表，并且我不希望在每个位置复制列表处理代码。我试图在这种没有完全崩溃的函数（如下）中调用我最好的方法导致了这个错误：

警告：List.Test 操作失败。重载解析失败，因为无法使用以下参数调用公共“ProcessList”：“公共共享函数 ProcessList(Of t)(_func As Func(Of Object,t), _list As System.Object) As IEnumerable(Of t)”：参数匹配参数“_func”的类型参数推断失败。

Iterator Function ProcessList(Of t)(_func As Func(Of Object, t), _list As Object) As IEnumerable(Of t)
    If _list.GetType = GetType(List(Of t)) Then
        Yield _list.SelectMany(Function(l) ProcessList(_func, l))
    Else
        Yield _func(_list)
    End If
End Function

作为参考，我发现了一段 Python 代码可以有效地满足我的需要，但是我对这个方向的翻译（Python 到 VB.net）有点生疏，而且我对这种类型的编程并不熟悉VB.net。Python 代码段是：

def ProcessList(_func, _list):
    return map(lambda x: ProcessList(_func, x) if type(x)==list else _func(x), _list)

任何关于我需要如何调用这个函数的帮助，或者如果我的方法有缺陷如何重做这个函数，将不胜感激！

更新：

我重新检查了我是如何调用函数的，以及基于@djv 的我的方法正在工作的信息的其他一些事情。首先，由于我如何与这些函数交互的性质，我必须通过以下方式公开上述函数：

Public Shared Function Foo(ByVal _input As Object) As Object
    Return Utilities.ProcessList(AddressOf Bar, _input)
End Function

我现在也收到错误消息：

警告：List.Test 操作失败。无法将“System.Int32”类型的对象转换为“System.Collections.Generic.IList`1[System.Int32]”类型。

此时的问题可能在于我调用 ProcessList 函数的方法，而不是我想的函数本身。我正在与一个对自己调用 ProcessList 不满意的 GUI 进行交互，所以我需要这个中间“帮助器”函数，我显然没有正确使用它。

4

1 回答 1

0

你总是会得到一个IEnumerable(Of T)并且T可以是一个原始（即Integer）或原始列表（即List(Of Integer)）。因此，当您尝试使用 List 调用它时，您会得到一个List(Of List(Of Integer))例如。

我们可以通过ProcessList分成两种方法来了解原因。它们之间的区别在于第二个参数的类型是T或者IEnumerable(Of T)

Sub Main()
    Dim i As Integer = 1
    Dim li As New List(Of Integer) From {1, 1, 1}
    Dim ri As IEnumerable(Of Integer) = ProcessList(AddressOf foo, i).ToList()
    Dim rli As IEnumerable(Of Integer) = ProcessList(AddressOf foo, li).ToList()

    Dim d As Double = 1.0#
    Dim ld As New List(Of Double) From {1.0#, 1.0#, 1.0#}
    Dim rd As IEnumerable(Of Double) = ProcessList(AddressOf foo, d).ToList()
    Dim rld As IEnumerable(Of Double) = ProcessList(AddressOf foo, ld).ToList()

    Console.ReadLine()
End Sub

Function ProcessList(Of T)(f As Func(Of T, T), p As IEnumerable(Of T)) As IEnumerable(Of T)
    Return p.Select(Function(i) ProcessList(f, i)).SelectMany(Function(i) i)
End Function

Iterator Function ProcessList(Of T)(f As Func(Of T, T), p As T) As IEnumerable(Of T)
    Yield f(p)
End Function

Function foo(param As Integer) As Integer
    Return param + 1
End Function

Function foo(param As Double) As Double
    Return param + 1.0#
End Function

以前，我什至无法在您的原始代码中执行 SelectMany。现在，当调用正确的函数时它会被命中。我还重新调整了该调用以适应新的函数签名。

重载都被调用，基于传递给它们的第二个参数。但是，foo每个 T 只需要一个方法（原语或其 IEnumerable）。

于 2020-02-12T19:41:19.053 回答