4

我想在 F# 中编写一些通用函数和类型来处理向量。我有多种具有静态(+)和(*)运算符的不同数据类型，因此我可以将它们相加并乘以标量（float现在是 s ）。

例如，我已经成功Vec2构建了一个可以编写的类

let v = 3.0 * Vec2(1.,1.) + Vec2(3.,4.)

假设我也有一个Vec3或任何其他类型的向量。这是我想写的两个示例（伪代码）：

向量上的通用函数

我认为这对于 assert'V具有的静态解析类型约束是可能的(+)，(*)但我无法让它工作。如果我可以将我的类型约束命名如下，那就太好了。

let average<'V when 'V : vector> (v1:'V) (v2:'V) =
    0.5 * (v1 + v2)

有没有真正有效的替代方案？

本身是向量类型的泛型类型

对于任何类型'T和表示向量的类型，我们可以像向量一样'V添加和标量乘法函数。'T -> 'V我想建立一个像

type VecFunc<'T,'V when 'V : vector> = ...

举个简单的例子，f : VecFunc<int,Vec2>可以存储一个函数，该函数接受一个int x并返回一个Vec2两个分量都等于的函数float x。Eval也许我们可以通过调用一个方法来评估底层函数：

f.Eval(3) // would return Vec2(3.,3.)

我想把VecFunc<int,Vec2>它当作一个向量类型，给它(+)和(*)操作，这样我就可以计算

(-2.0 * f + f).Eval(2) // returns Vec2(-4., -4.)

或将其与第一个示例结合使用：

(average f g).Eval(1) // ...

有没有办法使用 F# 接口或类型参数来实现这些结果？

4

1 回答 1

3

您可以通过要求您的向量类型（以及向量上的函数）实现某些运算符来执行这些操作。根据您的示例，我想您已经有了+forVec2和*for 向量乘以标量。您可以根据这些运算符编写average函数，然后它将适用于具有这些运算符的任何类型。

唯一的问题是 F#*以某种特殊的方式处理，所以如果你有*type ，你就不能轻易做到这一点float * vector -> vector。如果您将标量用于向量乘法，它似乎工作正常.*（同样，您可以添加*.用于另一个方向）。

以下是我对这些运算符Vec2的定义：Vec3

type Vec2(a:float, b:float) = 
  member x.A = a
  member x.B = b
  static member (.*) (a:float, v:Vec2) = 
    Vec2(a*v.A, a*v.B)
  static member (+) (v1:Vec2, v2:Vec2) = 
    Vec2(v1.A+v2.A, v1.B+v2.B)

type Vec3(a:float, b:float, c:float) = 
  member x.A = a
  member x.B = b
  member x.C = c
  static member (.*) (a:float, v:Vec3) = 
    Vec3(a*v.A, a*v.B, a*v.C)
  static member (+) (v1:Vec3, v2:Vec3) = 
    Vec3(v1.A+v2.A, v1.B+v2.B, v1.C+v2.C)

现在您可以编写average为使用静态成员约束的内联函数：

let inline average (v1:^V) (v2:^V) =
  (^V : (static member (.*) : float * ^V -> ^V) (0.5, v1 + v2))

average (Vec2(1.,1.)) (Vec2(3.,4.))
average (Vec3(1.,1.,1.)) (Vec3(3.,4.,5.))

如果您使用运算符，F# 会自动添加一个约束+，所以我可以只写v1 + v2. 该.*运算符是非标准的，因此我必须显式调用它。

对于您问题的第二部分 - 正如您所指出的，F# 类型不能由具有静态类型约束的其他类型参数化，因此这样做需要更多技巧。您拥有的一种选择是将您需要的操作添加为类型的参数，然后使用一个inline函数来捕获操作并将它们作为常规函数传递给您的VecFunc类型。这是一个例子：

type VecFunc<'T1, 'T2>(f:'T1 -> 'T2, mult:float * 'T1 -> 'T1, add:'T2 * 'T2 -> 'T2) = 
  member x.F = f
  member x.Mult = mult
  member x.Add = add
  static member (.*) (a:float, f:VecFunc<_, _>) = 
    VecFunc((fun v -> f.F (f.Mult(a, v))), f.Mult, f.Add)
  static member (+) (f1:VecFunc<_, _>, f2:VecFunc<_, _>) = 
    VecFunc((fun v -> f1.Add(f1.F v, f2.F v)), f1.Mult, f1.Add)

let inline vfunc (f:^V -> ^T) = 
    VecFunc< ^V, ^T>(f, 
      (fun (a, b) -> (^V : (static member (.*) : float * ^V -> ^V) (a, b))),
      (fun (a, b) -> a + b))

let vf = vfunc (fun (v:Vec2) -> v + v)
average vf vf

这种类型检查，但我不确定它是否正确（我不确定向量函数的加法和乘法应该做什么！） - 但无论如何，它可能会帮助您找到正确的方向。

于 2019-10-29T23:43:05.900 回答