1

我有一个空位图，我有一个接收 TCanvas 的绘图例程。绘图程序是一个更大的库的一部分，因此实际上不受我的控制。

简单地说：如果绘图程序影响像素，我希望像素是不透明的；每个未被触摸的像素都应该保持透明。由于我无法控制绘图例程将使用的颜色，因此我宁愿不必使用该TransparentColor属性。

有没有办法实现这一目标？我可以使用某种设置来指定画布应该影响它绘制到的像素的 alpha 层？

更新：我使用的是 Delphi 2010，下面是我尝试过的代码：

Bmp := TBitmap.Create;
try
  Bmp.PixelFormat := pf32bit;
  Bmp.Transparent := False;
  Bmp.SetSize(Width, Height);

  // Ensure all pixels are black with opacity 0 (= fully transparent)
  ScanlineWidth := Width * SizeOf(TRGBQuad);
  for y := 0 to Bmp.Height - 1 do begin
    ZeroMemory(Bmp.ScanLine[y], ScanlineWidth);
  end;

  // call drawing routines here
  DrawContours(Bmp.Canvas, Width, Height);

  {$IFDEF DEBUG}
  Bmp.SaveToFile(OwnPath + 'Contours-' + IntToStr(GetTickCount) + '.bmp');
  {$ENDIF}

  Result := Bmp.ReleaseHandle;
finally
  Bmp.Free;
end;
4

3 回答 3

1

如果我理解正确：
您每次都会得到一个完全透明的位图。

建议
您可以重写该DrawContours函数以为其绘制的画布的每个区域设置一个 alpha 值。我会建议这条路线，但我认为您在某处提到您不想重写这些函数。

我能想到的唯一其他选择是（因为你的开始 bmp 全黑且全透明）在将它传递给DrawContrours函数后检查每个像素，如果它不再是黑色，则将 alpha 更改为 255。但这有与仅使用您已经说过不想使用的透明颜色和属性的结果相同。

想法：
我不知道有一种方法（甚至怀疑是否有一种方法）来更改位图，以便您将其传递给的任何绘图例程都会以不同于设计例程的方式对待它。

最终答案：
重写绘图程序DrawContrours或使用Transparent color

于 2011-04-27T13:27:38.420 回答
1

如果绘图不昂贵，则可以选择以下方法。绘制三遍，一次在透明位图上，一次在白色背景的 1 位位图上，一次在黑色背景的 1 位位图上，以获得您需要对 Alpha 通道进行的更改（因为 Tim 是对的 -位图最初是完全透明的；我们需要找到像素以使其不透明）。

编辑：第一个版本仅使用一个具有白色背景的 1 位位图。不幸的是，这没有检测到较轻的绘画。因此，让我们更进一步，使其成为两个 1 位位图。尽管随着越来越多的位图，它变得同样不那么优雅。

var
  Bmp: TBitmap;
  ScanlineWidth: Integer;
  x: Integer;
  y: Integer;
  // this one will track dark paintings
  BmpBitMaskWhite:TBitmap;
  // this one will track light paintings
  BmpBitMaskBlack:TBitmap;
  Row32bit, Row1bitWhite, Row1bitBlack:PByteArray;
  ByteAccess:Byte;

  // Init bitmaps needed for tracking pixels we need to change the alpha channel for
  procedure InitAlphaMaskBitmaps;
  begin
    BmpBitMaskWhite.PixelFormat:=pf1bit;          // <= one bit is enough
    BmpBitMaskWhite.Transparent:=False;
    BmpBitMaskWhite.SetSize(Width, Height);
    BmpBitMaskWhite.Canvas.Brush.Color:=clWhite;  // <= fill white; changes can then be seen as black pixels
    BmpBitMaskWhite.Canvas.FillRect(Rect(0,0,Width, Height));

    BmpBitMaskBlack.PixelFormat:=pf1bit;          // <= one bit is enough
    BmpBitMaskBlack.Transparent:=False;
    BmpBitMaskBlack.SetSize(Width, Height);
    BmpBitMaskBlack.Canvas.Brush.Color:=clBlack;  // <= fill black; changes can then be seen as white pixels
    BmpBitMaskBlack.Canvas.FillRect(Rect(0,0,Width, Height));
  end;

begin
  Bmp := TBitmap.Create;
  BmpBitMaskWhite:=TBitmap.Create;
  BmpBitMaskBlack:=TBitmap.Create;
  try
    Bmp.PixelFormat := pf32bit;
    Bmp.Transparent := False;
    Bmp.SetSize(Width, Height);

    InitAlphaMaskBitmaps;

    // ensure all pixels are black with opacity 0 (= fully transparent)
    ScanlineWidth := Width * SizeOf(TRGBQuad);
    for y := 0 to Bmp.Height - 1 do
    begin
      ZeroMemory(Bmp.ScanLine[y], ScanlineWidth);
    end;

    // call drawing routines here
    DrawContours(Bmp.Canvas, Width, Height);
    // call again to get areas where we need to un-transparent the Bmp (this is for dark paintings)
    DrawContours(BmpBitMaskWhite.Canvas, Width, Height);
    // call again to get areas where we need to un-transparent the Bmp  (this is for light paintings)
    DrawContours(BmpBitMaskBlack.Canvas, Width, Height);

    // modify alpha channel of Bmp by checking changed pixels of BmpBitMaskWhite and BmpBitMaskBlack
    // iterate all lines
    for y := 0 to Bmp.Height - 1 do
    begin
      // iterate all pixels
      for x := 0 to Bmp.Width - 1 do
      begin
        Row32bit:=PByteArray(Bmp.ScanLine[y]);
        Row1bitWhite:=PByteArray(BmpBitMaskWhite.ScanLine[y]);
        Row1bitBlack:=PByteArray(BmpBitMaskBlack.ScanLine[y]);

        // Now we need to find the changed bits in BmpBitMaskWhite and BmpBitMaskBlack to modify the corresponding
        // alpha-byte in Bmp. Black areas (Bit=0) in BmpBitMaskWhite are the ones that
        // have been drawn to, as well as white areas (Bit=1) in BmpBitMaskBlack.
        // Not pretty, but works.
        ByteAccess:=1 shl (7-x mod 8);
        if ((Row1bitWhite[x div 8] and ByteAccess)=0) or
           ((Row1bitBlack[x div 8] and ByteAccess)<>0) then
        begin
          Row32bit[x*4+3]:=255;
        end;
      end;
    end;

    {$IFDEF DEBUG}
    Bmp.SaveToFile('C:\Temp\Contours-' + IntToStr(GetTickCount) + '.bmp');
    BmpBitMaskWhite.SaveToFile('C:\Temp\Contours-' + IntToStr(GetTickCount) + '_BitMaskWhite.bmp');
    BmpBitMaskBlack.SaveToFile('C:\Temp\Contours-' + IntToStr(GetTickCount) + '_BitMaskBlack.bmp');
    {$ENDIF}

//    Result := Bmp.ReleaseHandle;
  finally
    Bmp.Free;
    BmpBitMaskWhite.Free;
    BmpBitMaskBlack.Free;
  end;

顺便说一句：唯一能正确显示这些位图中透明度的程序是PixelFormer。其他的（Gimp、IrfanView、Windows Fax thingy、FastStone Image Viewer、MS Paint）都将透明区域涂成黑色。

于 2011-04-27T14:58:26.340 回答
0

在摆弄了几个选项之后，我得到了以下工作：

  • 将像素格式设置为 32 位；
  • 设置AlphaFormat为afIgnored;
  • 设置Transparent为真；（这个很重要）
  • 清除 alpha 值；
  • 调用绘图例程；
  • 然后将位图分配给 PNG，然后保存。

在代码中：

Bmp := TBitmap.Create;
try
  Bmp.PixelFormat := pf32bit;
  Bmp.AlphaFormat := afIgnored;
  Bmp.Transparent := True;

  Bmp.SetSize(Width, Height);

  // Make bitmap fully transparent
  ScanlineWidth := Width * SizeOf(TRGBQuad);
  for y := 0 to Bmp.Height - 1 do begin
    ZeroMemory(Bmp.ScanLine[y], ScanlineWidth);
  end;

  DrawContours(Bmp.Canvas);

  PNG := TPNGImage.Create;
  try
    PNG.Assign(Bmp);
    PNG.SaveToFile('contours.png'); // => this one has the wanted transparency!
  finally
    PNG.Free;
  end;
finally
  Bmp.Free;
end;
于 2011-04-27T14:30:40.740 回答