0

我在http://blog.armbruster-it.de/2010/07/getting-a-list-of-all-i18n-properties-used-in-a-grails-application/上找到了这个很棒的 gant 脚本，谢谢 Stefan ！

描述：创建 groovy 代码和 gsp 模板中使用的所有 i18n 属性的列表

def properties = []

new File(".").eachFileRecurse {
    if (it.file) {
        switch (it) {
            case ~/.*\.groovy/:
                def matcher = it.text =~ /code:\s*["'](.*?)["']/
                matcher.each { properties << it[1] }
                break
            case ~/.*\.gsp/:
                def matcher = it.text =~ /code=["'](.*?)["']/
                matcher.each { properties << it[1] }
                break
        }
    }
}
println properties.sort().unique().join("\n")

我尝试通过以下方式扩展它。假设我们有一些消息属性，例如：

message(code: 'product.label', default: 'Product')

我们希望作为脚本输出的内容类似于：

product.label=Product

我试图在正则表达式中添加一些条件：

def matcher = it.text =~ /code=["'](.*?)["'] | default=\s*["'](.*?)["']/

并将其填充到属性中。但是由于正则表达式没有找到成对的“代码和默认”部分，所以这是行不通的。

知道如何更改正则表达式或整个脚本来做到这一点吗？

4

4 回答 4

2

您的正则表达式不正确。对于以下消息方法调用：

message(code: 'product.label', default: 'Product')

它应该如下所示：

def properties = [:]
def txt = "message(code: 'product.label', default: 'Product')"
def matcher = txt =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
matcher.each{ properties[it[1]] = it[2] }
assert properties == ['product.label':'Product']
于 2011-04-19T18:44:41.110 回答
1

除了像 bunting 那样提供更好的正则表达式之外，我还发现了一个非常有用的 Grails 插件：message-reports

于 2011-04-19T20:39:48.503 回答
0

解决它的更好的正则表达式是：

/code=["'](.*?)["'].*default=\s*["'](.*?)["']/

输出格式可以是

properties << it[1]+"="+it[2]

结果

product.label=Product
于 2011-04-20T09:16:18.103 回答
0

我对这个脚本做了一些工作，发现了一些需要注意的细节。我想找到有和没有定义默认值的消息，我也想找到非标记版本（即${g.message(code:"the.code", default:"the.default"}）。

最好不要检查文件的内容，而是逐行解析它。这是因为如果一行中有代码，我将（在第二步中）查看它是否有默认值。不想解析整个文件两次。

def properties = [:]

new File(".").eachFileRecurse { file ->
    if (file.file) {
        switch (file) {
            case ~/.*\.groovy/:
                file.eachLine {line ->
                    // check if there is a message in the current line
                    def matcherNoDefault = line =~ /code:\s*["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }
                }
                break
            case ~/.*\.gsp/:
                file.eachLine {line ->
                    // check if there is a message in the current line (as a g.message(...) function)
                    def matcherNoDefault = line =~ /code:\s*["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }

                    // check if there is a message in the current line (in tag form)
                    matcherNoDefault = line =~ /code=["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code=["'](.*?)["'].*default=["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }
                }
        }
    }
}
println properties.each {k, v ->
    println("${k}=${v}")
}

像这样，我不能在一行中混合使用和不使用默认值的消息。我现在可以忍受。

玩得开心！

于 2013-03-11T11:22:10.423 回答