1

我需要在单个数据库字段中存储两个值（是的，我同意这是不好的做法，但这是一个无法更改的遗留数据库）。数据存储为string1#4string2.

需要使用两个单独的TcxDBTextEdit控件来编辑数据。但是如何将它们连接到单个数据库字段，以便我可以string1在一个和string2另一个中进行编辑？

我尝试向 中添加两个计算 ( fkCalculated) 字段，在/TADOQuery中提取/加入它们的值并读取/写入，但它没有用。OnGetTextOnSetTextTStringField

所以我尝试创建一个TdxMemData包含两个字段的组件并使用它们而不是计算字段，但它仍然不起作用。

我怎样才能做到这一点（不改变数据库结构）？

4

1 回答 1

1

下面的示例项目可以满足您的需求。

更新下面的代码替换了我最初发布的代码，并避免使用支持 fkInternalCalc 字段的数据集类型（TClientDataSet）。它将 与 TAdoQuery 一起使用。

尽管原则上将字符串字段解析为两个子字段并在您的 gui 中显示它们以进行编辑没有困难，但使用 TAdoQuery 执行此操作的直接方法的问题在于它仅支持 fkCalculated 计算字段和 db-aware gui 控件处理这些是用户不可修改的。

我不确定为什么存在这种限制，但我想这与 Delphi 的 db-aware 控件最初是为 BDE 开发的事实有关（并且在添加 fkInternalCalc 以支持 TClientDataSet 之前的情况下）。DB.Pas 中强制执行限制的代码位于 DB.Pas 中：

function TField.GetCanModify: Boolean;
begin
  if FieldNo > 0 then
    if DataSet.State <> dsSetKey then
      Result := not ReadOnly and DataSet.CanModify else
      Result := IsIndexField
  else
    Result := False;
end;

下面的代码通过为 TStringField 添加一个插入器类来工作，该类消除了对 FieldKind 为 fkCalculated 的字符串字段的限制，这些字符串字段不是 ReadOnly 并且属于可修改的数据集（尽管我认为可以删除后一个限制）。插入器 TStringField 覆盖GetCanModify如下：

function TStringField.GetCanModify: Boolean;
begin
  if (FieldKind = fkCalculated) and DataSet.CanModify and not ReadOnly then
    Result := True
  else
  if DataSet.State <> dsSetKey then
    Result := not ReadOnly and DataSet.CanModify else
    Result := IsIndexField
end;

示例项目的完整代码如下。请注意，我使用了常规的 TDBEdits，因为我当前的 Devex 设置存在问题，但代码也可以与 TcxDBEdit 一起正常工作。

代码：

type
  TStringField = class(db.TStringField)
  protected
    function GetCanModify : Boolean; override;
  end;

type
  TForm1 = class(TForm)
    DBGrid1: TDBGrid;
    DBNavigator1: TDBNavigator;
    DataSource1: TDataSource;
    DBEdit1: TDBEdit;
    DBEdit2: TDBEdit;
    ADOQuery1: TADOQuery;
    cxDBMaskEdit1: TcxDBMaskEdit;
    DBEdit3: TDBEdit;
    btnDataLinks: TButton;
    ADOConnection1: TADOConnection;
    ADOQuery1ID: TIntegerField;
    ADOQuery1Field1: TWideStringField;
    ADOQuery1Field2: TWideStringField;
    ADOQuery1SubField1: TStringField;
    ADOQuery1SubField2: TStringField;
    procedure FormCreate(Sender: TObject);
    procedure ADOQuery1BeforePost(DataSet: TDataSet);
    procedure ADOQuery1CalcFields(DataSet: TDataSet);
  private
    procedure UpdateSubFields(DataSet : TDataSet);
    procedure UpdateField1(DataSet: TDataSet);
  end;

[...]
const
  scSeparator = '#4';   // could be a literal #4 instead

procedure TForm1.UpdateField1(DataSet : TDataSet);
var
  S : String;
begin
  if DataSet.FieldByName('SubField1').IsNull or DataSet.FieldByName('SubField2').IsNull then exit;

  S := DataSet.FieldByName('SubField1').AsString + scSeparator +
    DataSet.FieldByName('SubField2').AsString;
  S := Trim(S);
  if Length(S) > DataSet.FieldByName('Field1').Size then
    raise exception.Create('tthe combined size of the subfields is too long');

  DataSet.FieldByName('Field1').AsString := S;
end;

procedure TForm1.UpdateSubFields(DataSet : TDataSet);
var
  S,
  SF1,
  SF2 : String;
  P,
  SF2Start : Integer;
begin
  S := DataSet.FieldByName('Field1').AsString;
  P := Pos(scSeparator, S);
  SF1 := Copy(S, 1, P-1);
  SF1 := Trim(SF1);
  SF2Start :=  P + Length(scSeparator);
  SF2 := Copy(S, Sf2Start, Length(S));
  SF2 := Trim(SF2);

  DataSet.FieldByName('SubField1').AsString := SF1;
  DataSet.FieldByName('SubField2').AsString := SF2;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  AdoQuery1.Open;
end;

procedure TForm1.CDS1CalcFields(DataSet: TDataSet);
begin
  UpdateSubFields(DataSet);
end;

function TStringField.GetCanModify: Boolean;
begin
  if (FieldKind = fkCalculated) and DataSet.CanModify and not ReadOnly then
    Result := True
  else
  if DataSet.State <> dsSetKey then
    Result := not ReadOnly and DataSet.CanModify else
    Result := IsIndexField
end;

procedure TForm1.ADOQuery1BeforePost(DataSet: TDataSet);
begin
  UpdateField1(AdoQuery1);
end;

procedure TForm1.ADOQuery1CalcFields(DataSet: TDataSet);
begin
  UpdateSubFields(DataSet);
end;
于 2019-06-28T13:41:31.943 回答