13

我正在创建一个 API，并在每个方法中调用一个日志记录方法以进行审计和故障排除。就像是：

<cffunction name="isUsernameAvailable">
    <cfset logAccess(request.userid,"isUsernameAvailable")>
    ......
</cffunction>

我想避免手动重复方法名称。有没有办法以编程方式确定它？

我查看了 GetMetaData() 但它只返回有关组件的信息（包括所有方法），但没有返回有关当前正在调用的方法的信息。

4

4 回答 4

12

所以现在有3种方式。

如果您使用的是 ColdFusion 9.0 或更高版本，现在有一个名为 GetFunctionCalledName() 的函数。它会返回你正在寻找的东西。 http://help.adobe.com/en_US/ColdFusion/9.0/CFMLRef/WS7cc222be8a31a47d-6e8b7083122cebfc8f2-8000.html

或者

使用 ColdSpring 和面向方面的编程 ( http://www.coldspringframework.org/coldspring/examples/quickstart/index.cfm?page=aop ) 为您处理这个问题。

或者

使用 cfthrow 生成包含信息的堆栈跟踪：

<cffunction name="determineFunction" output="FALSE" access="public"  returntype="string" hint="" >
<cfset var functionName ="" />
<cfset var i = 0 />
<cfset var stackTraceArray = "" />
<cftry>
<cfthrow />
<cfcatch type="any">
    <cfset stacktraceArray = ListToArray(Replace(cfcatch.stacktrace, "at ", " | ", "All"), "|") />

    <!---Rip the right rows out of the stacktrace --->
    <cfloop index ="i" to="1" from="#ArrayLen(stackTraceArray)#" step="-1">
        <cfif not findNoCase("runFunction", stackTraceArray[i]) or FindNoCase("determineFunction", stackTraceArray[i])>
            <cfset arrayDeleteAt(stackTraceArray, i) />
        </cfif>
    </cfloop>

    <!---Whittle down the string to the func name --->
    <cfset functionName =GetToken(stacktraceArray[1], 1, ".") />
    <cfset functionName =GetToken(functionName, 2, "$")/>
    <cfset functionName =ReplaceNoCase(functionName, "func", "", "once")/>

    <cfreturn functionName />
</cfcatch>
</cftry></cffunction>

我的建议是使用 getFunctionCalledName，或者如果不在 CF 9 ColdSpring 上，它可能会为您购买一些其他东西。

于 2009-02-20T01:37:55.827 回答
4

我同意 tpryan。ColdSpring 使这变得非常容易。但是，这是另一种选择。您可以解析 CFC 文件本身，而不是解析堆栈跟踪。

<cffunction name="foo" displayname="foo" hint="this is just a test function" access="public" returntype="string">
    <cfset var test = getFunctionName(getMetaData().path, getPageContext().getCurrentLineNo()) />
    <cfreturn test />
</cffunction>

<cffunction name="getFunctionName" hint="returns the function name based on the line number" access="public" returntype="string">
    <cfargument name="filepath" type="string" required="true" />
    <cfargument name="linenum" type="any" required="true" />
    <cfset var line = "" />
    <cfset var functionName = "" />
    <cfset var i = 1 />
    <!---- loop over CFC by line ---->
    <cfloop file="#ARGUMENTS.filepath#" index="line">
        <cfif findNoCase('cffunction', line, 1)>
            <cfset functionName = line />
        </cfif>
        <cfif i EQ ARGUMENTS.linenum><cfbreak /></cfif>
        <cfset i++ />
    </cfloop>
    <!---- parse function name ---->
    <cfset functionName = REMatchNoCase("(\bname=[""|'])+[a-z]*[""|']", functionName) />
    <cfset functionName = REMatchNoCase("[""']+[a-z]*[""']", functionName[1]) />
    <cfset functionName = ReReplaceNoCase(functionName[1], "[""']", "", "all") />
    <!---- return success ---->
    <cfreturn functionName />
</cffunction>

以上是为 ColdFusion 8 编写的。CFLOOP 添加了对逐行循环文件的支持（并且不会将整个文件读入内存）。我做了一些比较堆栈跟踪方法和文件解析的测试。在直接从单个 CFM 模板调用的小型 CFC 上，两者的表现同样出色。显然，如果您有非常大的 CFC，则解析方法可能会慢一些。另一方面，如果您有大量堆栈跟踪（例如，如果您使用任何流行的框架），那么文件解析可能会更快。

-= Viva ColdFusion =-

于 2009-02-20T03:42:57.850 回答
1

我想到了另一种可行的方法。

设置一个 OnMissingMethod 是这样的：

<cffunction name="onMissingMethod">
    <cfargument name="missingMethodName" type="string"> 
    <cfargument name="missingMethodNameArguments" type="struct">

    <cfset var tmpReturn = "">
    <cfset var functionToCallName = "Hidden" & Arguments.missingMethodName>
    <cfset arguments.missingMethodArguments.calledMethodName = Arguments.missingMethodName>
    <cfinvoke method="#functionToCallName#" argumentcollection="#Arguments.missingMethodArguments#" returnvariable="tmpReturn" />
    <cfreturn tmpReturn>
</cffunction>

然后用前缀（在本例中为“隐藏”）命名每个常规方法，并将它们标记为私有。所以我最初的例子会变成：

<cffunction name="HiddenisUsernameAvailable" access="private">
    <cfset logAccess(request.userid,Arguments.calledMethodName)>
    ......
</cffunction>

现在所有的调用都将被 onMissingMethod 拦截，它将方法名称添加到传递给真实方法的参数中。

我看到的缺点是内省不再正常工作，您必须使用命名参数来调用所有函数。如果您不使用命名参数，则参数将在 missingMethodNameArguments 结构中随机更改顺序。

于 2009-02-22T19:28:16.627 回答
1

那么你可以试试这个：

 <cffunction name="getFunctionName" returntype="any">
        <cfset meta =getMetaData(this)> 
        <cfreturn meta.functions[numberOfFunction].name>
    </cffunction>

我尝试了各种方法，但这是不准确的，因为这些函数似乎是按字母倒序添加到函数数组中的。这似乎是有限的（并没有解决问题）。我想可以调用一些本机 Java 代码，但我需要研究一下。

This和This看起来像是对相关内部函数的有趣阅读。

回复：关于冷泉的另一个答案。我发现这篇关于带有冷泉的函数元数据的深入文章。

相关问题：如何获取在 ColdFusion 中扩展我的组件的名称？

于 2009-02-20T00:24:34.723 回答