7

我试图了解证明在 Coq 提取中的作用。我有以下取自此处的整数除以二的示例。对于我的第一次尝试，我使用了Admitted关键字：

(*********************)
(* div_2_even_number *)
(*********************)
Definition div_2_even_number: forall n,
  (Nat.Even n) -> {p:nat | n=p+p}.
Proof.
Admitted.

(*************)
(* test_even *)
(*************)
Definition test_even: forall n,
  {Nat.Even n}+{Nat.Even (pred n)}.
Proof.
Admitted.

(********************)
(* div_2_any_number *)
(********************)
Definition div_2_any_number (n:nat):
  {p:nat | n = p+p}+{p:nat | (pred n) = p+p} :=
  match (test_even n) with
  | left h => inl _ (div_2_even_number n h)
  | right h' => inr _ (div_2_even_number (pred n) h')
  end.

(***************************)
(* Extract to Haskell file *)
(***************************)
Extraction "/home/oren/some_file.hs" div_2_any_number.

当我检查生成的 Haskell 文件时，我发现它确实丢失了：

div_2_even_number :: Prelude.Integer -> Prelude.Integer
div_2_even_number =
  Prelude.error "AXIOM TO BE REALIZED"

test_even :: Prelude.Integer -> Prelude.Bool
test_even =
  Prelude.error "AXIOM TO BE REALIZED"

div_2_any_number :: Prelude.Integer -> Prelude.Either Prelude.Integer
                    Prelude.Integer
div_2_any_number n =
  case test_even n of {
   Prelude.True -> Prelude.Left (div_2_even_number n);
   Prelude.False -> Prelude.Right (div_2_even_number (pred n))}

所以我想OK，让我们证明div_2_even_number：

(*********************)
(* div_2_even_number *)
(*********************)
Definition div_2_even_number: forall n,
  (Nat.Even n) -> {p:nat | n=p+p}.
Proof.
  intros n0 H.
  unfold Nat.Even in H.
  destruct H as [m0].
  exists m0.
Qed.

但我收到以下错误：

Error: Case analysis on sort Set is not allowed for inductive definition ex.

这里发生了什么？我显然在这里遗漏了一些东西。

4

2 回答 2

8

虽然 chi 说的是对的，但在这种情况下，您实际上可以p从存在证明中提取证人。当您有一个布尔谓词P : nat -> boolif 时exists p, P p = true，您可以p通过从 0 运行以下函数来计算满足谓词的一些：

find p := if P p then p else find (S p)

你不能直接在 Coq 中编写这个函数，但可以通过制作一个特殊的归纳命题来做到这一点。此模式在数学组件库的选择模块中实现：

From mathcomp Require Import ssreflect ssrfun ssrbool ssrnat eqtype choice.

(* == is the boolean equality test *)
Definition even n := exists p, (n == 2 * p) = true.

Definition div_2_even_number n (nP : even n) : {p | (n == 2 * p) = true} :=
  Sub (xchoose nP) (xchooseP nP).

该xchoose : (exists n, P n = true) -> nat函数执行上述搜索，并xchooseP显示其结果满足布尔谓词。（实际的类型比这更通用，但是当实例化nat它们时会产生这个签名。）我使用了布尔相等运算符来简化代码，但也可以使用它来=代替。

话虽如此，如果您关心运行代码，那么以这种方式编程效率非常低：您需要执行n / 2 nat比较来测试 divide n。编写除法函数的简单类型版本要好得多：

Fixpoint div2 n :=
  match n with
  | 0 | 1 => 0
  | S (S n) => S (div2 n)
  end.
于 2019-04-26T15:25:22.327 回答
6

您正在使用不同种类的类型。

> Check (Nat.Even 8).
Nat.Even 8
     : Prop

> Check {p:nat | 8=p+p}.
{p : nat | 8 = p + p}
     : Set

Coq 类型系统的一个特点是，您不能消除类型为 in 的值Prop以获取类型不 in 的值Prop（大致 - Coq 对Prop不携带信息的类型做了一些例外，例如Trueand False，但我们是在那种情况下不是）。粗略地说，除了证明另一个命题之外，您不能将命题证明用于任何事情。

不幸的是，这个限制是Prop不言而喻的（我们希望forall P: Prop, P->P成为 sort 中的类型Prop）并与排中律保持一致。我们不能拥有一切，否则我们会遇到 Berardi 悖论。

于 2019-04-26T12:55:47.990 回答